Form Controls not updated from Class methods

Question

I am a newcomer to Visual Studio 2013, so my question is probably -and hopefully- a simple one.

I am currently writing a small program (in VB) that will essentially add/update/delete users from a table.

The main form has three TextBoxes (ID#, name, last name), a button to check if the user already exists and a couple more buttons (Save and Cancel)

I have also created a Class (dataLookup) where all the functions for adding, updating or deleting users are stored.

The way the program works is as follows:

1.- The user enters an ID# in the main Form's ID field and clicks on the "check user" button.

2.- The system calls a function stored in the datalookup Class that verifies if the ID# already exists.

3.- If it does, the function retrieves the name and last name from the table, assigns them to two local variables (vName and vLastName) populates the corresponding fields on the Main Form and returns TRUE. User can then either update data or Cancel (See code sample below)

MainFormName.TextBox1.Text = vName
MainFormName.TextBox2.Text = vLastName
return True

4.- If the ID# doesn't exist, the function returns FALSE. User is then able to enter new data in the three textboxes.

My problem is that I can't populate the TextBox fields from the function stored in the dataLookup Class. After the instructions are processed, the TextBoxes (which are both Enabled and have their Read Only property set to false) remain empty.

If I add the exact same code that populates the fields to the Main Form code, and assign values to the vName and vLastName variables, it works perfectly:

vName = "John"
vLastName = "Doe" 
MainFormName.TextBox1.Text = vName
MainFormName.TextBox2.Text = vLastName

FYI, no errors are reported when I compile/run the program.

I am aware that I can modify the function so it will also return the name and last name and then I will be able to update the TextBox fields from the Main Form, but I am just curious: Why can't I do that from the function stored in the Class?

Hope my description was reasonably clear :) Any help will be much appreciated. Many thanks in advance!

Randy

Answer 1

Forms are classes (it says so at the top of each of them):

Public Class MainForm
  ....

As a class, an instance should be created however, VB allows what is called a default instance using the class name: MainForm.Show()

Under the hood, the compiler creates an instance of MainForm named MainForm and uses it. This is handy for developers hobbyists dabbling in code, but there are numerous ways this can bite you:

Sub DoSomeThing()
    Dim frm As New Form1
    frm.TextBox1.Text = cp.ToString
End Sub

Here a local instance of Form1 is created and used which has no relation to the Global Form1 which VB created. The local object goes out of scope at the end of the Sub never to be used by the rest of the app.

' in sub main:
Application.Run(New Form1)     ' main form/pump

... elsewhere
Form1.TextBox1.Text = "hello, world!"

In spite of using the same name, these are actually different instances. The text will not show up and if the next line was Form1.Show(), a second copy of Form1 would display complete with the 'hello, world' text. These will also create/show new instances:

Form2.Show()

' or
Dim frm As New Form2
frm.Show()

---

In general, the more complex the app, the less appropriate using default instances is. For serious apps, create explicit form instances:

Dim myFrm = New Form7()     ' myFrm is an instance of Form7
 ...
myFrm.TextBox1.Text = vName
myFrm.TextBox2.Text = vLastName
myFrm.Show

Classes or other forms can be told about this form various ways such as via a property or the constructor:

Class Foo
    Private myFrm As Form7

    Public Sub New(frm As Form7)
        myFrm = frm
    End Sub
    ...
End Class

Dim myFoo = New Foo(Me)

For the main/startup form, it can help to create a global reference:

Module Program
    Friend frmMain As MainForm
End Module

Then set the variable when the main form loads:

Public Class MainForm
   Private Sub MainForm_Load(sender ...)

       frmMain = Me
   End Sub
   ...

frmMain will be a valid reference to the main form for the entire application.