CODEWITHSUNDEEP
systemclipsexpert-system
Yatiac
Yatiac

Reputation: 2020

First CLIPS code doesnt work

I wrote my first CLIPS code for a school project but I am not familiar with CLIPS (I use C# and python as main languages).

This is my code and the errors I am gettin:

(defrule determine-closing-date
    (not (day-to-close ?))
    (billing-size ?)
    (unpaid-invoices-number ?)
    =>
    (if 
        (or 
            (< billing-size 1000000)
            (< unpaid-invoices-number 1000000)
        )
        then (assert (day-to-close MtTh))
        else (assert (day-to-close friday))
    )

(defrule determine-billing-size ""
    (not (billing-size ?))
    (not (day-to-close ?))
    =>
    (printout t "¿Cuál es el tamaño de la facturacion?")
    (assert (billing-size ?size (read))))

(defrule determine-unpaid-invoices-number ""
    (not (unpaid-invoices-number ?))
    (not (day-to-close ?))
    =>
    (printout t "¿Cuál es la cantidad de facturas no pagadas")
    (assert (unpaid-invoices-number ?size (read))))

(defrule determine-friday-load ""
    (day-to-close friday)
    (not (friday-load ?))
    =>
    (printout t "¿Cuál es la carga de cierres para el viernes?")
    (assert (friday-load ?load (read))))

(defrule determine-saturday-closing ""
    (day-to-close friday)
    (not(< friday-load 1000000))
    =>
    (assert (day-to-close saturday)))

(defrule day-to-close-conclulssion ""
    (day-to-close ?)
    =>
    (if (eq day-to-close MtTh) 
        then (printout t "Se puede cerrar de Lunes a Jueves")
        else (
            if (eq day-to-close friday) 
                then (printout t "Se debe cerrar viernes.") 
                else (printout t "Se debe cerrar sabado.")
             )
    ))

The errores are:

[ARGACCES5] Function < expected argument #1 to be of type integer or float

[PRCCODE3] Undefined variable size referenced in RHS of defrule.

[CSTRCPSR1] WARNING: Redefining defrule: determine-saturday-closing +j+j+j

[CSTRCPSR1] WARNING: Redefining defrule: day-to-close-conclulssion +j+j

Upvotes: 0

Views: 1614

Answers (1)

Gary Riley
Gary Riley

Reputation: 10757

Some suggest revisions:

(defrule determine-closing-date
    (not (day-to-close ?))
    (billing-size ?billing-size)
    (unpaid-invoices-number ?unpaid-invoices-number)
    =>
    (if (or (< ?billing-size 1000000)
            (< ?unpaid-invoices-number 1000000))
        then (assert (day-to-close MtTh))
        else (assert (day-to-close friday))))

(defrule determine-billing-size ""
    (not (billing-size ?))
    (not (day-to-close ?))
    =>
    ; What is the size of the billing?
    (printout t "¿Cuál es el tamaño de la facturacion? ")
    (bind ?size (read))
    (assert (billing-size ?size)))

(defrule determine-unpaid-invoices-number ""
    (not (unpaid-invoices-number ?))
    (not (day-to-close ?))
    =>
    ; What is the amount of unpaid bills?
    (printout t "¿Cuál es la cantidad de facturas no pagadas? ")
    (bind ?size (read))
    (assert (unpaid-invoices-number ?size)))

(defrule determine-friday-load ""
    (day-to-close friday)
    (not (friday-load ?))
    =>
    ; What is the burden of closures for Friday?
    (printout t "¿Cuál es la carga de cierres para el viernes? ")
    (bind ?load (read))
    (assert (friday-load ?load)))

(defrule determine-saturday-closing ""
    ?dtc <- (day-to-close friday)
    (friday-load ?load&:(< ?load 1000000))
    =>
    (retract ?dtc)
    (assert (day-to-close saturday)))

(defrule day-to-close-conclusion ""
    (declare (salience -10))
    (day-to-close ?day-to-close)
    =>
    (switch ?day-to-close
       (case MtTh 
             ; Can be closed from Monday to Thursday.
             then (printout t "Se puede cerrar de Lunes a Jueves." crlf))
       (case friday 
             ; Must be closed Fridays.
             then (printout t "Se debe cerrar viernes." crlf))
       (default 
             ; Must be closed Saturday.
             then (printout t "Se debe cerrar sabado." crlf))))

And the output it produces:

CLIPS> Loading Buffer...
******
CLIPS> (reset)
CLIPS> (run)
¿Cuál es el tamaño de la facturacion? 10
¿Cuál es la cantidad de facturas no pagadas? 10
Se puede cerrar de Lunes a Jueves.
CLIPS> (reset)
CLIPS> (run)
¿Cuál es el tamaño de la facturacion? 3000000
¿Cuál es la cantidad de facturas no pagadas? 3000000
¿Cuál es la carga de cierres para el viernes? 10
Se debe cerrar sabado.
CLIPS> (reset)
CLIPS> (run)
¿Cuál es el tamaño de la facturacion? 3000000
¿Cuál es la cantidad de facturas no pagadas? 3000000
¿Cuál es la carga de cierres para el viernes? 3000000
Se debe cerrar viernes.
CLIPS>

Upvotes: 2

Related Questions