ArgumentOutOfRangeException when trying to clear combobox

Question

I'm having the following error message appear when trying to run .Clear() on my combobox:

A first chance exception of type 'System.ArgumentOutOfRangeException' occurred in System.Windows.Forms.dll {"InvalidArgument=Value of '-1' is not valid for 'index'. Parameter name: index"}

The strange part is, it does the .Clear() before going to the new 'page' in the application, and it works without a problem. Once I'm on the 'page', draw the items in the combobox and try to go to the next 'page' of the application, it calls the function with the clear once again and blows up when it gets to the .Clear(). If I comment out the cbo.DrawMode = DrawMode.OwnerDrawFixed in the code below it also runs as normal, so the problem is definitely with drawing the strings in the combobox (I'm drawing the strings to change the colour of them). Anyways, completely stumped as to how to fix this, any help would be appreciated.

Code is below:

-My clear method

Public Sub ClearCombos()
    'Clear Applicant Combos

    cboPrimary.Items.Clear() 'crashes when it hits this line
    cboJoin1.Items.Clear()
    cboJoin2.Items.Clear()
    cboJoin3.Items.Clear()
    cboJoin4.Items.Clear()
End Sub

• Drawing the strings in the comboboxes

  Sub CheckForAgeOverage()
  
  c_applicants = {cboPrimary, cboJoin1, cboJoin2, cboJoin3, cboJoin4}
  
  Dim curdate As Date = Date.Now
  Dim age As Integer
  
  counter = 0
  'Check age of applicants
  For Each cbo As ComboBox In c_applicants
      If CKeyValuePair.GetComboBoxSelectedKey(c_applicants(counter), True) = instApplicant.applicantId Then
          age = Math.Floor(DateDiff(DateInterval.Month, DateValue(instApplicant.BirthDate), curdate) / 12)
          If age >= 70 Then
              overArray.Add(CKeyValuePair.GetComboBoxSelectedValue(c_applicants(counter)))
          End If
          cbo.DrawMode = DrawMode.OwnerDrawFixed
  
      Else
          For Each j As JoinsBU In instJoins
              If CKeyValuePair.GetComboBoxSelectedKey(c_applicants(counter), True) = j.Applicant.applicantId Then
                  age = Math.Floor(DateDiff(DateInterval.Month, DateValue(j.Applicant.BirthDate), curdate) / 12)
                  If age >= 70 Then
                      overArray.Add(CKeyValuePair.GetComboBoxSelectedValue(c_applicants(counter)))
                  End If
                  cbo.DrawMode = DrawMode.OwnerDrawFixed
              End If
          Next
      End If
      counter += 1
  Next
  End Sub
  

• The Comboboxes DrawItem event:

  Private Sub cbo_DrawItem(sender As System.Object, e As System.Windows.Forms.DrawItemEventArgs) Handles cboPrimary.DrawItem, cboJoin1.DrawItem, cboJoin2.DrawItem, cboJoin3.DrawItem, cboJoin4.DrawItem
  
  Dim brush As Brush = Brushes.Black
  
  Dim text As String = (CType(sender, ComboBox)).Items(e.Index).ToString()
  counter = 0
  
  For Each s As String In overArray
      If text = overArray(counter) Then
          brush = Brushes.Red
      Else
          brush = Brushes.Black
      End If
      counter += 1
  Next
  
  e.Graphics.DrawString(sender.Items(e.Index).ToString(), e.Font, brush, _
  e.Bounds, StringFormat.GenericDefault)
  counter = 0
  
  End Sub
  

Answer 1

It looks like this shouldn't happen, but it obviously is. The actual error might be in this line in the DrawItem handler:

Dim text As String = (CType(sender, ComboBox)).Items(e.Index).ToString()

Try separating the assignment out of the Dim statement, and check the value of e.Index to make sure it is non-negative. If that's the problem, you could probably work around it with an if to make sure e.Index is non-negative.