ASP Contact form error Server object error 'ASP 0177 : 800401f3'

Question

One of my websites contact/reservations form has suddenly stopped working and I now receive the following error.

Server object error 'ASP 0177 : 800401f3' 

Server.CreateObject Failed 

/contact2.asp, line 51

I've done a bit of research and it seems to relate to classic ASP commands but my knowledge of ASP is limited.

Here is the full code:-

<%

name = request.form("name")
email = request.form("email")
phone = request.form("phone")
guests = request.form("guests")
datum2 = request.form("datum2")
info = request.form("info")
time_hour = request.form.item("time_hour")
time_minute = request.form.item("time_minute")
moda_event = request.form.item("modaEvent")
sign_up = request.form.item("signup")

If name="" or email="" Then
url = "reservations.asp?reqd=* indicates required field&name=" & mname    & "&email=" & memail
If name="" Then 
url = url & "&mname=*"
End if

If email="" Then
url = url & "&memail=*"
End if

response.redirect url & "&foobar=foobar#form"
response.end
End if


         Dim objCDONTS                 ' Email object
                 Dim strFromName               ' From persons' real name
                 Dim strFromEmail, strToEmail  ' Email addresses
                 Dim strSubject, strName, strPhone, strEmail, strGuests, strDate, strHour, strMinute, strEvent, strInfo, strSignup 'Message
                 Dim misccompo       


         strSubject    = "Reservation Form"
         strFromName   = Trim(Request.Form("name"))
         strFromEmail  = Trim(Request.Form("email"))
         strToEmail    = "reservations@modarestaurant.co.uk"
         strName       = Trim(Request.Form("name")) 
         strPhone      = Trim(Request.Form("phone"))
         strEmail  = Trim(Request.Form("email")) 
         strGuests     = Trim(Request.Form("guests")) 
         strDate       = Trim(Request.Form("datum2")) 
         strHour       = Trim(Request.Form.Item("time_hour")) 
         strMinute     = Trim(Request.Form.Item("time_minute")) 
         strEvent      = Trim(Request.Form.Item("moda_event")) 
         strInfo       = Trim(Request.Form("info"))
         strSignup = Trim(Request.Form.Item("signup"))  

Set objCDONTS = Server.CreateObject("CDONTS.NewMail")
                         objCDONTS.From    = strFromName & " <" &   strFromEmail & ">"
                         objCDONTS.To      = strToEmail
                         objCDONTS.Subject = strSubject
             objCDONTS.Body    = "--------------------------------------" & vbcrlf & vbcrlf & "Name: " & strName & vbcrlf & "Contact Number: " & strPhone & vbcrlf & "Email Address: " & strEmail & vbcrlf & "No. of Guests: " & strGuests & vbcrlf & "Date: " & strDate & vbcrlf & "Time: " & strHour & ":" & strMinute & vbcrlf & "Event: " & strEvent & vbcrlf & "Additional Info: " & vbcrlf & strInfo & vbcrlf & "Newsletter Signup: " & strSignup &vbcrlf  & "--------------------------------------------------------------" & vbcrlf & "MESSAGE ENDS: End of info"
                         objCDONTS.Send
                         Set objCDONTS = Nothing

response.redirect "thank-you.asp"
response.end
%>

The line 51 error is this line;

Set objCDONTS = Server.CreateObject("CDONTS.NewMail")

Any help would be greatly appreciated.

Answer 1

The error

Server object error 'ASP 0177 : 800401f3' 

Server.CreateObject Failed 

/contact2.asp, line 51

means that the object could not be created because it could not find the appropriate DLL for the object requested. In other words, it is looking for the CDONTS COM component that was included with NT SP4 as the file cdont.dll. CDONTS was deprecated in Windows 2000 and completely removed in Windows 2003. Therefore, if you are using Window 2003, Windows 2008 or Windows 2012 server this error makes sense since the DLL is not present.

To fix this problem try the following - use CDOSYS. CDOSYS (cdosys.dll) is a library file provided as part of IIS for Windows 2000, Windows 2003 Server, and Windows 2008 Server. This DLL enabled applications to route SMTP messages across multiple platforms and added much more functionality over the older CDONTS library.

Here is a greatly simplified example to model some changes on

Dim Message As New CDO.Message

sch = "http://schemas.microsoft.com/cdo/configuration/"

Set cdoConfig = CreateObject("CDO.Configuration")

with cdoConfig.Fields
    .item(sch & "sendusing") = 2
    .Item(sch & "smtpserver") = "mail.xxxx.com" ' your SMTP mail server
    .Item(sch & "smtpserverport") = 2525
    .update
end with

'Create CDO message object
Set Message = CreateObject("CDO.Message")
With Message
    set .configuration = cdoConfig

    'Set email adress, subject And body
    .From = strFromName   
    .To = strToEmail    
    .Subject = strSubject    
    .TextBody = TextBody

    'Send the message
    .Send
End With