Delphi Twebbrowser Identify html element id

Question

All, we have an RFID application that is web based. We are trying to make display boards across our facility that shows information. I'm trying to make the webpage auto-login but I'm not having any luck. I've tried enumerating all tags/elements on the page but I'm not having any luck.

Access violation with the line below (because the element j_username isn't found, but it's clearly in the html snippet. I know I'm missing something simple. Can someone please help?

 WebBrowser1.OleObject.Document.GetElementByID('j_username').
     setAttribute('value', 'dempseyw');

here is the login code from the page I am trying to automate.





        MobileView
        
    
    
        
        
            
                
            
        

        
            
            
        


        
            
                
                    

                    
                        
                            

                            
                            
                        
                    
                    
                
                


                
                    
                

                User Name:
                    

                    

                    
Password:
                    

                    

                        
                            
                            Remember me on this computer

crefird · Accepted Answer

You have to locate the form, then you can locate and set the value of the element within the form.

Navigate to the webpage with TWebBrowser, then try the following. Note, this does not consider the possibility of frames.

function GetFormByNumber(document: IHTMLDocument2; formNumber: integer)
  : IHTMLFormElement;
var
  Forms: IHTMLElementCollection;
begin
  Forms := document.Forms as IHTMLElementCollection;
  if formNumber < Forms.Length then
    Result := Forms.item(formNumber, '') as IHTMLFormElement
  else
    Result := nil;
end;

procedure SetFieldValue(theForm: IHTMLFormElement; const fieldName: string;
  const newValue: string);
var
  field: IHTMLElement;
  inputField: IHTMLInputElement;
  selectField: IHTMLSelectElement;
  textField: IHTMLTextAreaElement;
begin
  field := theForm.item(fieldName, '') as IHTMLElement;
  if Assigned(field) then
  begin
    if field.tagName = 'INPUT' then
    begin
      inputField := field as IHTMLInputElement;
      inputField.Value := newValue;
    end
    else if field.tagName = 'SELECT' then
    begin
      selectField := field as IHTMLSelectElement;
      selectField.Value := newValue;
    end
    else if field.tagName = 'TEXTAREA' then
    begin
      textField := field as IHTMLTextAreaElement;
      textField.Value := newValue;
    end;
  end
  else
    raise Exception.Create('HTML Field not found: ' + fieldName);
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  doc: IHTMLDocument2;
  theForm: IHTMLFormElement;
begin
  doc := WebBrowser.Document as IHTMLDocument2;
  theForm := GetFormByNumber(doc, 0);
  SetFieldValue(theForm,'j_username','dempseyw');
  SetFieldValue(theForm,'j_password','pw');
  theForm.submit;
end;

Delphi Twebbrowser Identify html element id

Answers (1)

Related Questions