CODEWITHSUNDEEP
stringperlcsvstring-formatting
Meeyaw
Meeyaw

Reputation: 75

format the following result file into a tabular format using Perl

I have a sort of a problem, and I am still novice with Perl.

I just want to ask how can I format the following results file into an Excel readable format (let's say CSV).

Result file example. llq1_dly.mt0

$MEAS COMMANDS SOURCE='llq1_dly.meas' DB FILE='clk_top_45h_lpe_sim.fsdb'
.TITLE '**-------------'
    tdrll10_0        tdfll10_0        tdrll10_1        tdfll10_1        tdrll10_2        tdfll10_2        tdrll10_3
 2.106560e-10     1.990381e-10     2.102583e-10     1.986280e-10     2.095036e-10     1.978480e-10     2.083813e-10

into the following file with a result like this one below

llq1_dly,tdr,tdf,
ll10_0,2.106560e-10,1.990381e-10,
ll10_1,2.102583e-10,1.986280e-10,
ll10_2,2.095036e-10,1.978480e-10,
ll10_3,2.083813e-10,1.967019e-10,
...

or more likely this one (to be compatible with engineering scientific notations):

llq1_dly,tdr,tdf,
ll10_0,210.6560e-12,199.0381e-12,
ll10_1,210.2583e-12,198.6280e-12,
ll10_2,209.5036e-12,197.8480e-12,
ll10_3,208.3813e-12,196.7019e-12,
...

Upvotes: 1

Views: 112

Answers (1)

Borodin
Borodin

Reputation: 126722

Here's a program that produces the output you ask for. I don't generally approve of offering answers to questions where the OP hasn't made any attempt to write a solution themselves, but this question interested me.

It may well be that this could be written more simply, but you don't say what parts of the input are invariant. For instance, I have written it so that there can be any number of different columns with any names, rather than just tdr and tdf every time. As it is I have had to guess that the trailing part of each header ends in ll, so for instance tdrll10_0 is tdr and ll10_0. If that is wrong then you will need a different way of splitting the string.

I have written the program so that it reads from the DATA file handle. I trust you are able to write an open statement to read from the correct input file?

I hope this helps

use strict;
use warnings;
use 5.010;

use Number::FormatEng 'format_eng';
Number::FormatEng::use_e_zero();

my $fh = \*DATA;

my ($source, @headers, @values);
while ( <$fh> ) {
  if ( /SOURCE=(?|'([^']+)'|"([^"]+)")/ ) { #' code highlighting fix
    ($source = $1) =~ s/\.[^.]*\z//;
  }
  elsif ( /^\.TITLE/ ) {
    @headers = split ' ', <$fh>;
    @values  = split ' ', <$fh>;
    last;
  }
}

my @title = ( $source );
my (%headers, @table, @line);
for my $i ( 0 .. $#headers) {
  my @fields = split /(?=ll)/, $headers[$i];
  if ( $headers{$fields[0]} ) {
    push @table, [ @line ];
    @line = ();
    %headers = ();
  }
  ++$headers{$fields[0]};
  push @line, $fields[1] if @line == 0;
  push @line, format_eng($values[$i]);
  push @title, $fields[0] unless @table;
}
print "$_," for @title;
print "\n";

for ( @table ) {
  print "$_," for @$_;
  print "\n";
}

__DATA__
$MEAS COMMANDS SOURCE='llq1_dly.meas' DB FILE='clk_top_45h_lpe_sim.fsdb'
.TITLE '**-------------'
    tdrll10_0        tdfll10_0        tdrll10_1        tdfll10_1        tdrll10_2        tdfll10_2        tdrll10_3
 2.106560e-10     1.990381e-10     2.102583e-10     1.986280e-10     2.095036e-10     1.978480e-10     2.083813e-10

output

llq1_dly,tdr,tdf,
ll10_0,210.656e-12,199.0381e-12,
ll10_1,210.2583e-12,198.628e-12,
ll10_2,209.5036e-12,197.848e-12,

Upvotes: 1

Related Questions