Gravity / velocity & jump issue (AS3, platformer)

Question

I'm currently trying to program a flash game for Android.

I have more or less working gravity & velocity and hit tests - so I don't fall through my platforms.

The problem now is, as soon as I hit "jump", the hit test stops working and i fall through the platforms. If I set my character to a different, higher position I don't even fall down.

Can anyone help me figure this out?

Here is my code:

import flash.events.MouseEvent;
import flash.events.Event;


var gravity:Number = 2;
var velocity:Number = 1.1;
var jumpPower:Number = 0;
var isJumping:Boolean = false;


stage.addEventListener(Event.ENTER_FRAME, touchPlatform);
player.addEventListener(Event.ENTER_FRAME, appeal);

function touchPlatform(e:Event):void
    {
        if(kurz.hitTestObject(player))
            {
                hitPlatform = true;
                }

        else if(kurz2.hitTestObject(player))
            {
                hitPlatform = true;
                }

        }

function appeal(e:Event):void                               
    {
        gravity *= velocity;    
        player.y += gravity;                                

        if(hitPlatform == true)
        {
            velocity = 0;
            }

    }


jump.addEventListener(MouseEvent.CLICK, doJump);
stage.addEventListener(Event.ENTER_FRAME, update);
function doJump(e:MouseEvent):void
{
    if(!isJumping)
    {
        jumpPower = 30;
        isJumping = true;
        }
    }

function update(e:Event):void
    {
        if(isJumping)
        {
            player.y -= jumpPower;
            jumpPower -= 2;

            }

        else
        {
            isJumping = false;
            }
        }

Answer 1

Your issue is that once you start jumping, you never stop! No where (that can be reached) do you set isJumping to false. Also, your jumping value and your gravity are currently running in tandem, you only want one OR the other affecting your player at any given time.

Try something like this (see code comments for explainations)

import flash.events.MouseEvent;
import flash.events.Event;


var gravity:Number = 2;
var velocity:Number = 1.1;
var jumpPower:Number = 0;
var isJumping:Boolean = false;

jump.addEventListener(MouseEvent.CLICK, doJump);
function doJump(e:MouseEvent):void {
    if(!isJumping){
        jumpPower = 30;
        isJumping = true;
    }
}


//Just one ENTER_FRAME handler is better, 
//then you have more control over the order in which code gets run
//I've combined your three into one and called it gameLoop
stage.addEventListener(Event.ENTER_FRAME, gameLoop);

function gameLoop(e:Event):void {
    //this is the same, I just combined your 2 if's into one.
    if(kurz.hitTestObject(player) || kurz2.hitTestObject(player)){
        hitPlatform = true;
    }                             

    //you should set the velocity before assigning it to the player
    if(hitPlatform == true){
        velocity = 0;
        gravity = 2; //you probably want to reset gravity to default too
        isJumping = false; //SET isJumping to false now that you've hit a platform!  <-------------
    }else{
        velocity = 1.1; //you need to reset velocity when not on a platform
    }


    //Now that we've determined the velocity and if we're jumping, let's move the player the appropriate amount

    if(isJumping){
        //Since we're currently jumping, use the jumpPower instead of gravity
        player.y -= jumpPower;
        jumpPower -= 2;
    }else{
        if(!hitPlatform){
            //Since we're NOT JUMPING, and not on a platform, use gravity.
            gravity *= velocity;    
            player.y += gravity;  
        }
    }
}