CODEWITHSUNDEEP
arraysloopscountsas
user3581800
user3581800

Reputation: 317

Count the number of times a value occurs

I have 7 variables, 489 observations with variable values of 0-4. What I need is the count percentage of use. Answers 0,1 stand for non usage, and answers 2,3,4 stand for usage. I created 7 additional vars and turned all the values above to: 1=usage - 0=non-usage. Now, I don't know how to count and present how many "1" I have for each var and divide it by 489. 

    data LAB7;
    set LAB3;
    array v{*} v21-v27;
    array VU{7};
    DO i=1 to dim(v);
     if v[i] = 1|0 THEN VU[i]=0;
     else VU[i]=1;
    END; 
    run;

Upvotes: 0

Views: 778

Answers (1)

Alex A.
Alex A.

Reputation: 5586

You can do this:

data usage;
    set lab3 end=eof;

    array v{*} v21-v27
    array n{7};

    retain n: 0;

    do i = 1 to dim(v);
        if v[i] in (2, 3, 4) then n[i] + 1;
    end;

    if eof then do j = 1 to dim(v);
        variable = vname(v[j]);
        pct_usage = 100 * n[j] / _n_;
        output;
    end;

    keep variable pct_usage;
run;

This creates an array of counters, one per variable, that are incremented by one whenever the corresponding variable is equal to 2, 3, or 4.

At the end of the data step, we output a record for each variable and record the percentage as the counter divided by the number of observations (_n_ when eof is true).

An alternative would be to use proc freq.

data indicators;
    set lab3;
    array v{*} v21-v27;
    array ind{7};
    do i = 1 to dim(v);
        ind[i] = (v[i] in (2, 3, 4));
    end;
run;

proc freq data = indicators;
    tables ind: / out = usage;
run;

This creates binary indicator variables, one for each of the input variables, that are 1 when the input is 2, 3, or 4, and 0 otherwise. Counts and percentages are then obtained using proc freq.

Upvotes: 3

Related Questions