How do I access a method of ClassA from classB?

Question

I didn't really know what exactly to ask in the question. So I am going to explain everything here:

I am working on a Desktop AIR Database Application I have a Class named "Database Screen" which is linked to a movie clip:

package  {
import flash.display.MovieClip;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.display.InteractiveObject;
import flash.filesystem.File;
import flash.filesystem.FileStream;
import flash.filesystem.FileMode;
import flash.utils.Timer;
import flash.events.TimerEvent;
import flash.text.TextField;

public class DatabaseScreen extends MovieClip {

    private var allButtons:Array;
    private var codeSelected:Boolean;
    private var nameSelected:Boolean;
    private var xmlDatabase:XML;
    private var dbFile:File;
    public var xmlList:XMLList;
    private var totalProducts:uint;
    private var totalItems:uint = 0;
    private var productExists:Boolean;
    private var productId:Number;
    private var XMLReader:xmlReader;

    public function DatabaseScreen() {
        allButtons = [searchPanel.search_btn, addNewPanel.addNew_btn, dbStatsPanel.xls_btn, searchPanel.code_radio, searchPanel.name_radio];
        init();
    }

    private function init():void
    {
        XMLReader = new xmlReader();
        //adding event listeners..
        for(var i:int = 0; i<allButtons.length; i++)
        {
            allButtons[i].addEventListener(MouseEvent.MOUSE_OVER, onOver, false, 0, true);
            allButtons[i].addEventListener(MouseEvent.MOUSE_OUT, onOut, false, 0, true);
            allButtons[i].addEventListener(MouseEvent.MOUSE_DOWN, onDown, false, 0, true);
            allButtons[i].addEventListener(MouseEvent.MOUSE_UP, onUp, false, 0, true);
            allButtons[i].addEventListener(MouseEvent.CLICK, onClick, false, 0, true);
            allButtons[i].buttonMode = true;
        }

        //creating a new file for the database
        dbFile = File.documentsDirectory.resolvePath("BlackCat/Database.xml");
        xmlDatabase = new XML();
        getXML();
        saveXML();
        getTotalItems();
        dbStatsPanel.items.text = String(totalItems);
    }
    private function getXML():void
    {
        if(dbFile.exists)
        {
            var stream:FileStream = new FileStream();
            stream.open(dbFile, FileMode.READ);
            xmlDatabase = new XML(stream.readUTFBytes(stream.bytesAvailable));
            stream.close();
            xmlList = xmlDatabase.Product;
            dbStatsPanel.products.text = xmlList.length();
            XMLReader.xmlData = xmlList;
            XMLReader.updateXMLList(xmlList);

        }
        else
        {
            xmlDatabase = <Products></Products>
        }
    }
    public function getXMlList():XMLList
    {
        return xmlList;
    }
    private function getTotalItems():void
    {
        for(var i:int = 0; i < xmlList.length(); i++)
        {
            totalItems += uint(xmlList[i].@Qty);
        }
    }
    private function saveXML():void
    {
        var stream:FileStream = new FileStream();
        stream.open(dbFile, FileMode.WRITE);
        stream.writeUTFBytes(xmlDatabase.toXMLString());
    }
    private function onDown(evt:MouseEvent):void
    {
        evt.target.scaleX = evt.target.scaleY = .8;
    }
    private function onUp(evt:MouseEvent):void
    {
        evt.target.scaleX = evt.target.scaleY = 1;

    }
    private function onOver(evt:MouseEvent):void
    {
        evt.target.alpha = .5;
    }
    private function onOut(evt:MouseEvent):void
    {
        evt.target.alpha = 1;
        evt.target.scaleX = evt.target.scaleY = 1;
    }
    private function onClick(evt:MouseEvent):void
    {
        switch(evt.target.name)
        {
            case "code_radio":
                codeSelected = true;
                nameSelected = false;
                searchPanel.code_radio.gotoAndStop(1);
                searchPanel.name_radio.gotoAndStop(2);
            break;

            case "name_radio":
                nameSelected = true;
                codeSelected = false;
                searchPanel.code_radio.gotoAndStop(2);
                searchPanel.name_radio.gotoAndStop(1);
            break;

            case "addNew_btn":
                //Checking if the product already exists..
                for(var i:int = 0; i < xmlList.length(); i++)
                {
                    if(xmlList[i].@code == addNewPanel.add_code_txt.text)
                    {
                        productExists = true;
                        productId = i;
                    }
                }
                if(productExists)
                {
                    var PQty:uint = uint(xmlList[productId].@Qty);
                    var PQtoAdd:uint = uint(addNewPanel.add_qty_txt.text);
                    PQty += PQtoAdd;
                    xmlList[productId].@Qty = String(PQty);
                    productExists = false;
                }
                else
                {
                    xmlDatabase.appendChild(<Product code={addNewPanel.add_code_txt.text} 
                    name={addNewPanel.add_name_txt.text} Price={addNewPanel.add_price_txt.text} 
                    Qty={addNewPanel.add_qty_txt.text}></Product>);
                }
                totalItems += uint(addNewPanel.add_qty_txt.text);
                xmlList = xmlDatabase.Product;
                dbStatsPanel.products.text = xmlList.length();
                dbStatsPanel.items.text = String(totalItems);
                XMLReader.updateXMLList(xmlList);
                saveXML();
                trace(xmlDatabase);
            break;

        }
    }
    public function setVisiblity(visibility:Boolean):void
    {
        switch(visibility)
        {
            case true:
                this.visible = true;
            break;

            case false:
            this.visible = false;
            break;
        }
    }
    public function getXMLList():XMLList
    {
        return xmlList;
    }


}

}

And I have another class named "NewOrder", in this class I am trying to access the xmlList from the "DatabaseScreen" class but I am unable to do so.

package  {
import flash.display.MovieClip;
import flash.events.MouseEvent;
import com.greensock.TweenMax;
import flash.filesystem.File;
import flash.filesystem.FileStream;
import flash.filesystem.FileMode;


public class NewOrder extends MovieClip {
    private var allButtons:Array;
    private var shoppingCart:Array;
    private var scroller:FlickScroll;
    private var db:DatabaseScreen;
    private var XMLReader:xmlReader;

    public function NewOrder() {
        this.visible = false;

        init(db);
    }
    private function init(dbase:DatabaseScreen):void
    {
        XMLReader = new xmlReader();
        trace(XMLReader.xmlData);

        scroller = new FlickScroll(masker, container, 84.05, -500);
        addChild(scroller);
        allButtons = [scan_btn, print_invoice];
        shoppingCart = [];
        for(var i:int = 0; i < allButtons.length; i++)
        {
            allButtons[i].addEventListener(MouseEvent.MOUSE_OVER, onOver, false, 0, true);
            allButtons[i].addEventListener(MouseEvent.MOUSE_OUT, onOut, false, 0, true);
            allButtons[i].addEventListener(MouseEvent.MOUSE_DOWN, onDown, false, 0, true);
            allButtons[i].addEventListener(MouseEvent.MOUSE_UP, onUp, false, 0, true);
            allButtons[i].mouseChildren = false;
            allButtons[i].buttonMode = true;
        }
    }

    private function onOver(evt:MouseEvent):void
    {
        evt.target.alpha = .5;
    }
    private function onOut(evt:MouseEvent):void
    {
        evt.target.alpha = 1;
        evt.target.scaleX = evt.target.scaleY = 1;
    }
    private function onDown(evt:MouseEvent):void
    {
        evt.target.scaleX = evt.target.scaleY = .8;
    }
    private function onUp(evt:MouseEvent):void
    {
        evt.target.scaleX = evt.target.scaleY = 1;
        if(evt.target.name == "scan_btn")
        {
            var cartElement:CartElement = new CartElement();
            container.addChild(cartElement);
            cartElement.x = 0;
            cartElement.alpha = 0;
            TweenMax.to(cartElement, .4, {alpha:1});
            shoppingCart.push(cartElement);
            cartElement.id_txt.text = String(shoppingCart.length) + " - ";

            if(shoppingCart.length < 2)
            {
                cartElement.y = container.height - 30;
            }
            else
            {
                cartElement.y = container.height + 5;
            }

        }
    }
}

}

And there is a Main class in which I handle all the screens , e.g DatabaseScreen, NewOrder.. Which means I have added these to the display list in the Main class. To access the xmlList from the DatabaseScreen , I tried creating a new instance in the NewOrder class, but it creates to DatabaseScreen(s). I also tried creating another class named "xmlReader": package {

public class xmlReader {
    public var xmlData:XMLList;

    public function xmlReader() {

    }

    public function updateXMLList(updatedList:XMLList):void
    {
        xmlData = updatedList;
    }

}

}

In the databaseScreen class, as soon as I populate the xmlList , I set the xmlData of the xmlReader class equal to the xmlList from the databaseScreen class. And when I trace the XMLReader.xmlData in the databaseScreen , it works fine . But when I do the same thing in the NewOrder class, I get "null" in the output window. How do I solve this problem. Any help is greatly appreciated.

Answer 1

You will need to pass a reference into the Order class to have access to the DatabaseScreen class. Something like this.

var ds = new  DatabaseScreen();
var or = new NewOrder(ds)

Inside the NewOrder you can save the ref.

public class NewOrder {
    private var screens:DatabaseScreens;

    public function NewOrder(ds:DatabaseScreens) {
        screens = ds;
        // Now you can call screens.xmlList
    }
}