Mirlo
Mirlo

Reputation: 674

Parse a custom XML with as3

i have a XML and i didn't found a way how to parse it (read the data inside)

<Saa:Header>
        <Saa:Message>
            <Saa:SenderReference> data
             </Saa:SenderReference>
       </Saa:Message>
        <Saa:Message>
            <Saa:SenderReference> data
             </Saa:SenderReference>
       </Saa:Message>
  </Saa:Header>

i use the as3 language

Upvotes: 0

Views: 173

Answers (2)

BadFeelingAboutThis
BadFeelingAboutThis

Reputation: 14406

Going with your example in your question (which assumes your data is a string), you could do something along these lines:

//your xml needs a namespace identifier to be valid
//I've added one on the header node. 
//Likely if you're consuming this xml from some third party, the namespace declaration will be on root node.
var myXML = <Saa:Header xmlns:Saa="urn:swift:saa:xsd:saa.2.0" >
        <Saa:Message>
            <Saa:SenderReference> data
             </Saa:SenderReference>
       </Saa:Message>
        <Saa:Message>
            <Saa:SenderReference> data
             </Saa:SenderReference>
       </Saa:Message>
  </Saa:Header>;

//create a reference to the `Saa` namespace that prefixes all your xml nodes
var saaNamespace:Namespace = new Namespace("urn:swift:saa:xsd:saa.2.0");

//tell AS3 to use that namespace by default
default xml namespace = saaNamespace;

//basically an array of all the SenderReference nodes in the entire xml
var xmlList:XMLList = myXML..SenderReference; 

//This line will give the same results as the line above, but if there were SenderReference nodes somewhere else in the document that weren't under Message nodes, they would not be included (unlike above)
xmlList = myXML.Message.SenderReference; 

//iterate through all the SenderReference nodes
for(var i:int=0;i<xmlList.length();i++){
    trace("Node #" + (i+1) + ":",xmlList[i]);
}

There are lots of ways to get the data you want from XML in AS3, a good article is this one from senocular.

Upvotes: 1

null
null

Reputation: 5265

The XML class is the way.

[it] contains methods and properties for working with XML objects. The XML class (along with the XMLList, Namespace, and QName classes) implements the powerful XML-handling standards defined in ECMAScript for XML (E4X) specification (ECMA-357 edition 2).

Upvotes: 1

Related Questions