CODEWITHSUNDEEP
actionscript-3flashflash-cc
nikel
nikel

Reputation: 653

Dispatchevent not firing

I have a fla file and 2 class files. On my fla I have:

addEventListener(SubtitleLoadEvent.PASS_PARAMS, onProcessedEvent);

function onProcessedEvent(e:Event):void {
    trace(e.currentTarget);
}

SubtitleLoadEvent.as :

package
{
    import flash.events.Event;

    public class SubtitleLoadEvent extends Event
    {
        public static const PASS_PARAMS:String = new String("passparams");
        public var resultArr:Array = new Array();

        public function SubtitleLoadEvent(type:String, arr:*, bubbles:Boolean = false,
                                                cancelable:Boolean = false):void
        {
            this.resultArr = arr;
            super(type, bubbles, cancelable);
        }

        override public function clone():Event
        {
            return(new SubtitleLoadEvent(type, resultArr, bubbles, cancelable));
        }
    }
}

And I have a class file which extends sprite :

dispatchEvent(new SubtitleLoadEvent(SubtitleLoadEvent.PASS_PARAMS, cleanArr));

But the movie doesn't output anything. How can I fix this?

Upvotes: 1

Views: 345

Answers (1)

BadFeelingAboutThis
BadFeelingAboutThis

Reputation: 14406

Since your event doesn't bubble, the only way your timeline code will hear the event is if it was dispatched on the same scope (which is unlikely to be the case here).

If your dispatching sprite is on the same scope (timeline) or a descendant/child of it, then making the event bubble (third parameter when creating the event) should make it work. (or you could listen on the capture phase)

Otherwise, you will need to listen for the event on some common parent of both objects.

The easiest way to resolve this, is to dispatch and listen on the stage:

stage.addEventListener(SubtitleLoadEvent.PASS_PARAMS, onProcessedEvent);

stage.dispatchEvent(new SubtitleLoadEvent(SubtitleLoadEvent.PASS_PARAMS, cleanArr));

This assumes that your dispatching sprite has been added to the display list. If not, then the stage property will be null. If it's not on the display list, then it will not work.

TO learn more about how events work and their lifecycle, you could read this article.

Upvotes: 1

Related Questions