CODEWITHSUNDEEP
excel
Krisso123
Krisso123

Reputation: 175

Excel create date stamp when an cell is updated

I have this excel sheet that has a 'last updated' field in column N. I need to make this an automatic update to todays date, whenever the status in column H is changed for that row.

Can anyone help on a simple solution?

Thank you in advance! Kriss

enter image description here

Upvotes: 4

Views: 1787

Answers (1)

Gary's Student
Gary's Student

Reputation: 96753

Include the following event Macro in the worksheet code area:

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim rng As Range, r As Range, H As Range
  Set H = Range("H:H")
  Set rng = Intersect(H, Target)
  If rng Is Nothing Then Exit Sub

  Application.EnableEvents = False
  For Each r In rng
    Cells(r.Row, "N").Value = Date
  Next r
  Application.EnableEvents = True
End Sub

Because it is worksheet code, it is very easy to install and automatic to use:

  1. right-click the tab name near the bottom of the Excel window
  2. select View Code - this brings up a VBE window
  3. paste the stuff in and close the VBE window

If you have any concerns, first try it on a trial worksheet.

If you save the workbook, the macro will be saved with it. If you are using a version of Excel later then 2003, you must save the file as .xlsm rather than .xlsx

To remove the macro:

  1. bring up the VBE windows as above
  2. clear the code out
  3. close the VBE window

To learn more about macros in general, see:

http://www.mvps.org/dmcritchie/excel/getstarted.htm

and

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

To learn more about Event Macros (worksheet code), see:

http://www.mvps.org/dmcritchie/excel/event.htm

Macros must be enabled for this to work!

Upvotes: 2

Related Questions