CODEWITHSUNDEEP
polynomial-mathscilabapproximation
Spirine
Spirine

Reputation: 1877

How to make a polynomial approximation in Scilab?

I've a set of measures, which I want to approximate. I know I can do that with a 4th degree polynomial, but I don't know how to find it's five coefficients using Scilab.

For now, I must use the user-friendly functions of Open office calc... So, to keep using only Scilab, I'd like to know if a built-in function exists, or if we can use a simple script.

Upvotes: 2

Views: 12960

Answers (2)

Hani
Hani

Reputation: 301

The Atom's toolbox "stixbox" has Matlab-compatible "polyfit" and "polyval" functions included.

// Scilab 6.x.x need:
atomsInstall(["stixbox";"makematrix";"distfun";"helptbx";linalg"]) // install toolboxes

// POLYNOMINAL CURVE_FITTING
// Need toolboxes above

x = [-3 -1 0 1 3 5 7];
y = [50 74 62 40 19 35 52];
plot(x,y,".");           // plot sample points only

pcoeff = polyfit(x,y,4); // calculate polynominal coefficients (4th-degree)
xp = linspace(-3,7,100); // generate a little more x-values for a smoother curve fitting
yp = polyval(pcoeff,xp); // calculate the y-values for the curve fitting
plot(xp, yp,"k");        // plot the curve fitting in black

enter image description here

Upvotes: 4

user3717023
user3717023

Reputation:

There is no built-in polyfit function like in Matlab, but you can make your own:

function cf = polyfit(x,y,n)
A = ones(length(x),n+1)
for i=1:n
    A(:,i+1) = x(:).^i
end
cf = lsq(A,y(:))
endfunction

This function accepts two vectors of equal size (they can be either row or column vectors; colon operator makes sure they are column-oriented in the computation) and the degree of polynomial.

It returns the column of coefficients, ordered from 0th to the nth degree.

The computational method is straightforward: set up the (generally, overdetermined) linear system that requires the polynomial to pass through every point. Then solve it in the sense of least squares with lsq (in practice, it seems that cf = A\y(:) performs identically, although the algorithm is a bit different there).

Example of usage: 

x = [-3 -1 0 1 3 5 7]
y = [50 74 62 40 19 35 52]
cf = polyfit(x,y,4)

t = linspace(min(x),max(x))'   // now use these coefficients to plot the polynomial
A = ones(length(t),n+1)
for i=1:n
    A(:,i+1) = t.^i
end
plot(x,y,'r*')
plot(t,A*cf)

Output:

polynomial fit

Upvotes: 6

Related Questions