CODEWITHSUNDEEP
vbapowerpointpowerpoint-2013
dHumphrey
dHumphrey

Reputation: 307

Add PowerPoint slide to textbox with CommandButton VBA

I have a command button and a text-box in the Slide Master of a PowerPoint presentation. I am trying to retrieve the PowerPoint's properties such as SlideID, SlideIndex and the name of the corresponding file and post them to the text box on the click of the command button.

At the moment I have this code but its giving me an error: 

Sub CommandButton1_Click()
   Dim Index As Long
   Dim SlideId as Long
   Dim FileName as String 

   TextBox1.Text = "SlideIndex:" & Index & "Slide ID:" & SlideId 

End Sub

I want page 1 of the power point to read as slideIndex 1 SlideID 1 and the file name. and for slide 2 I want it to say all two's and so on...

Thanks in advance!

Upvotes: 0

Views: 1356

Answers (1)

Steve Rindsberg
Steve Rindsberg

Reputation: 14809

You can use a command button if you like; or you can use any PowerPoint shape you want to draw, assign it an Action Setting of Run Macro and choose the macro you want it to run when clicked.

Either way, this should work:

Sub ReportStuff()

    Dim oSl As Slide
    Dim oSh As Shape

    Set oSl = SlideShowWindows(1).View.Slide

    ' Test to see if the shape's already there:
    Set oSh = IsItThere(oSl, "My Text Box")

    ' If it's not there, add it:
    If oSh is Nothing Then
       Set oSh = oSl.Shapes.AddTextbox(msoTextOrientationHorizontal, 100, 100, 200, 50)
       oSh.Name = "My Text Box"
    End If

    With oSh.TextFrame.TextRange
        .Text = "Index: " & oSl.SlideIndex & " ID: " & oSl.SlideID & " File: " & ActivePresentation.FullName
    End With

End Sub

Function IsItThere(oSl as Slide, sName as String) as Shape
   Dim oSh as Shape
   For each oSh in oSl.Shapes
      If oSh.Name = sName Then
         Set IsItThere = oSh
         Exit Function
      End If
   Next
End Function

Upvotes: 0

Related Questions