CODEWITHSUNDEEP
vbscript
Humberto Freitas
Humberto Freitas

Reputation: 483

Disable "Make new folder" in Select Folder Dialog

I'm making a script that uses the dialog box below to select the folder where this run commands the problem is that it is not necessary as an option to create a new folder ... I wonder how can I remove the "make new folder"?

enter image description here

My Code:

Option Explicit

Dim strPath

strPath = SelectFolder( "" )
If strPath = vbNull Then
    WScript.Echo "Cancelled"
Else
    WScript.Echo "Selected Folder: """ & strPath & """"
End If


Function SelectFolder( myStartFolder )

    ' Standard housekeeping
    Dim objFolder, objItem, objShell

    ' Custom error handling
    On Error Resume Next
    SelectFolder = vbNull

    ' Create a dialog object
    Set objShell  = CreateObject( "Shell.Application" )
    Set objFolder = objShell.BrowseForFolder( 0, "Select Folder", 1, myStartFolder )

    ' Return the path of the selected folder
    If IsObject( objfolder ) Then SelectFolder = objFolder.Self.Path

    ' Standard housekeeping
    Set objFolder = Nothing
    Set objshell  = Nothing
    On Error Goto 0
End Function

Upvotes: 1

Views: 1455

Answers (1)

Ansgar Wiechers
Ansgar Wiechers

Reputation: 200443

When in doubt, read the documentation:

BIF_NONEWFOLDERBUTTON (0x00000200)

0x00000200. Version 6.0. Do not include the New Folder button in the browse dialog box.

Add 0x200 to the options parameter:

Set objFolder = objShell.BrowseForFolder(0, "Select Folder", &h201, myStartFolder)

Upvotes: 7

Related Questions