CODEWITHSUNDEEP
linuxbashperlshell
Cris
Cris

Reputation: 141

Executing a bash script from a Perl program

I'm trying to write a Perl program which will execute a bash script. The Perl script looks like this

#!/usr/bin/perl

use diagnostics;
use warnings;

require 'userlib.pl';
use CGI qw(:standard); 

ReadParse();

my $q = new CGI;
my $dir = $q->param('X');
my $s = $q->param('Y');

ui_print_header(undef, $text{'edit_title'}.$dir, "");

print  $dir."<br>";
print  $s."<br>";
print "Under Construction <br>";

use Cwd;
my $pwd = cwd();
my $directory = "/Logs/".$dir."/logmanager/".$s;
my $command = $pwd."/script ".$directory."/".$s.".tar";

print $command."<br>";
print $pwd."<br>";

chdir($directory);
my $pwd1 = cwd();
print $pwd1."<br>";

system($command, $directory) or die "Cannot open Dir: $!";

The script fail with the following error:

Can't exec "/usr/libexec/webmin/foobar/script
    /path/filename.tar": No such file or directory at /usr/libexec/webmin/foobar/program.cgi line 23 (#3)
(W exec) A system(), exec(), or piped open call could not execute the
named program for the indicated reason.  Typical reasons include: the
permissions were wrong on the file, the file wasn't found in
$ENV{PATH}, the executable in question was compiled for another
architecture, or the #! line in a script points to an interpreter that
can't be run for similar reasons.  (Or maybe your system doesn't support #!                  at all.)

I've checked that the permissions are correct, the tar file I'm passing to my bash script exists, and also tried from the command line to run the same command I'm trying to run from the Perl script ( /usr/libexec/webmin/foobar/script /path/filename.tar ) and it works properly.

Upvotes: 1

Views: 6184

Answers (3)

sandeep
sandeep

Reputation: 152

There are multiple ways to execute bash command/ scripts in perl.

  1. System
  2. backquate
  3. exec

Upvotes: 0

wallenborn
wallenborn

Reputation: 4273

In Perl, calling system with one argument (in scalar context) and calling it with several scalar arguments (in list context) does different things.

In scalar context, calling

system($command)

will start an external shell and execute $command in it. If the string in $command has arguments, they will be passed to the call, too. So for example

$command="ls /";
system($commmand);

will evaluate to

sh -c "ls /"

where the shell is given the entire string, i.e. the command with all arguments. Also, the $command will run with all the normal environment variables set. This can be a security issue, see here and here for a few examples why.

On the other hand, if you call system with an array (in list context), Perl will not call a shell and give it the $command as argument, but rather try to execute the first element of the array directly and give it the other arguments as parameters. So

$command = "ls";
$directory = "/";
system($command, $directory);

will call ls directly, without spawning a shell in between.

Back to your question: your code says

my $command = $pwd."/script ".$directory."/".$s.".tar";
system($command, $directory) or die "Cannot open Dir: $!";

Note that $command here is something like /path/to/script /path/to/foo.tar, with the argument already being part of the string. If you call this in scalar context

system($command)

all will work fine, because

sh -c "/path/to/script /path/to/foo.tar"

will execute script with foo.tar as argument. But if you call it in list context, it will try to locate an executable named /path/to/script /path/to/foo.tar, and this will fail.

Upvotes: 10

Cris
Cris

Reputation: 141

I found the problem. changed the system command removing the second parameter and now it's working

system($command) or die "Cannot open Dir: $!";

In fairness I did not understand what was wrong on first example but now works fine, if anyone can explain probably it can be interesting understand

Upvotes: 0

Related Questions