CODEWITHSUNDEEP
groovy
smeeb
smeeb

Reputation: 29487

Using Groovy collect closure to process list into grouped sublists

Given my Widget class:

class Widget {
    String name
    WidgetType type
    boolean isRad
}

enum WidgetType {
    Fizz, Buzz, Foo
}

My groovy code will be handed a List<Widget> that may be populated like so:

List<Widget> allWidgets = []
Widget w1 = new Widget(name: "W1", type: WidgetType.Fizz, isRad: true)
Widget w2 = new Widget(name: "W2", type: WidgetType.Fizz, isRad: true)
Widget w3 = new Widget(name: "W3", type: WidgetType.Buzz, isRad: false)
Widget w4 = new Widget(name: "W4", type: WidgetType.Buzz, isRad: false)
Widget w5 = new Widget(name: "W5", type: WidgetType.Foo, isRad: true)
Widget w6 = new Widget(name: "W6", type: WidgetType.Foo, isRad: false)

allWidgets << w1
allWidgets << w2
allWidgets << w3
allWidgets << w4
allWidgets << w5
allWidgets << w6

What I want to accomplish is the grouping of all elements in allWidgets according to their Widget#type. So effectively, turning the above list into multiple lists (1 per type) like so:

List<Widget> fizzWidgets = []
List<Widget> buzzWidgets = []
List<Widget> gooWidgets = []
Widget w1 = new Widget(name: "W1", type: WidgetType.Fizz, isRad: true)
Widget w2 = new Widget(name: "W2", type: WidgetType.Fizz, isRad: true)
Widget w3 = new Widget(name: "W3", type: WidgetType.Buzz, isRad: false)
Widget w4 = new Widget(name: "W4", type: WidgetType.Buzz, isRad: false)
Widget w5 = new Widget(name: "W5", type: WidgetType.Foo, isRad: true)
Widget w6 = new Widget(name: "W6", type: WidgetType.Foo, isRad: false)

fizzWidgets << w1
fizzWidgets << w2

buzzWidgets << w3
buzzWidgets << w4

fooWidgets << w5
fooWidgets << w6

I believe that the collect closure can be used here, but all my attempts thus far have failed, my best being:

allWidgets.collect { widget ->
    it.type
}

Any ideas what I can do here? And while I would accept a pure Java answer, I'm really hoping for something really elegant and...well, groovy.

Upvotes: 1

Views: 85

Answers (1)

Opal
Opal

Reputation: 84756

What you need is not collect but groupBy:

allWidgets.groupBy { it.type }

As a result a Map<WidgetType, List<Widget>> will be returned.

Demo:

enum WidgetType {
    Fizz, Buzz, Foo
}

class Widget {
    String name
    WidgetType type
    boolean isRad
}

List<Widget> allWidgets = [
    Widget w1 = new Widget(name: "W1", type: WidgetType.Fizz, isRad: true),
    Widget w2 = new Widget(name: "W2", type: WidgetType.Fizz, isRad: true),
    Widget w3 = new Widget(name: "W3", type: WidgetType.Buzz, isRad: false),
    Widget w4 = new Widget(name: "W4", type: WidgetType.Buzz, isRad: false),
    Widget w5 = new Widget(name: "W5", type: WidgetType.Foo, isRad: true),
    Widget w6 = new Widget(name: "W6", type: WidgetType.Foo, isRad: false),
]

def grouped = allWidgets.groupBy { it.type }
List<Widget> fizzWidgets = grouped[WidgetType.Fizz]
List<Widget> buzzWidgets = grouped[WidgetType.Buzz]
List<Widget> fooWidgets = grouped[WidgetType.Foo]

assert fizzWidgets.size() == 2
assert fizzWidgets.every { it.type == WidgetType.Fizz }
assert buzzWidgets.size() == 2
assert buzzWidgets.every{ it.type == WidgetType.Buzz }
assert fooWidgets.size() == 2
assert fooWidgets.every { it.type == WidgetType.Foo }


assert grouped instanceof Map
assert grouped.keySet().every { it instanceof WidgetType }
assert grouped.values().every { it instanceof List }
assert grouped.values().flatten().every { it instanceof Widget }

Here you can find groupBy docs.

Upvotes: 4

Related Questions