CODEWITHSUNDEEP
vim
Mert Nuhoglu
Mert Nuhoglu

Reputation: 10153

Recent file history in Vim?

I would like to access recent files that I had opened and then closed in GVim. I open and close GVim frequently. I would like to access recent files from previous sessions as well.

Does GVim store recent files somewhere as Word and many other desktop apps store? How to access them?

Upvotes: 160

Views: 85359

Answers (15)

Anton Samokat
Anton Samokat

Reputation: 1146

Redir function in the repository below will be able to show recent files list in a buffer similar to less. It will be handy with it to find file for opening.

Redirect the output of a Vim or external command into a scratch buffer

I will copy content of the current version of function Redir in the end of current post. Its code needs to be added to ~/.vimrc.

Add mappings to ~/.vimrc:

" show recent files, q to enter file number
nnoremap or :browse oldfiles<CR>
nnoremap rf :Redir browse oldfiles<CR>

In normal mode the following commands can be used:

  • or (open recent file) - to open recent file, q to enter file number to open
  • rf (recent files) - show full list with recent files, to search in it

Code of Redir function:

function! Redir(cmd, rng, start, end)
    for win in range(1, winnr('$'))
        if getwinvar(win, 'scratch')
            execute win . 'windo close'
        endif
    endfor
    if a:cmd =~ '^!'
        let cmd = a:cmd =~' %'
            \ ? matchstr(substitute(a:cmd, ' %', ' ' . shellescape(escape(expand('%:p'), '\')), ''), '^!\zs.*')
            \ : matchstr(a:cmd, '^!\zs.*')
        if a:rng == 0
            let output = systemlist(cmd)
        else
            let joined_lines = join(getline(a:start, a:end), '\n')
            let cleaned_lines = substitute(shellescape(joined_lines), "'\\\\''", "\\\\'", 'g')
            let output = systemlist(cmd . " <<< $" . cleaned_lines)
        endif
    else
        redir => output
        execute a:cmd
        redir END
        let output = split(output, "\n")
    endif
    vnew
    let w:scratch = 1
    setlocal buftype=nofile bufhidden=wipe nobuflisted noswapfile
    call setline(1, output)
endfunction

" This command definition includes -bar, so that it is possible to "chain" Vim commands.
" Side effect: double quotes can't be used in external commands
command! -nargs=1 -complete=command -bar -range Redir silent call Redir(<q-args>, <range>, <line1>, <line2>)

" This command definition doesn't include -bar, so that it is possible to use double quotes in external commands.
" Side effect: Vim commands can't be "chained".
command! -nargs=1 -complete=command -range Redir silent call Redir(<q-args>, <range>, <line1>, <line2>)

Upvotes: 0

Emile Vrijdags
Emile Vrijdags

Reputation: 1578

Adding my 2 cents here because fzf was was not mentioned in earlier answers, which is such a wonderful tool:
fzf.vim has a :History command that lets you search the most recent used files in a fuzzy and search while you type manner.
I customize the (default) behavior of this command by not letting fzf reorder the search results list to the best match: I want the order of all matching filenames to keep being the order in which these files were last used.
To accomplish this customization, I added the following in my .vimrc to override the default History command defined by the fzf.vim plugin:

    command! -bang -nargs=* History
      \ call fzf#vim#history({'options': '--no-sort'})

EDIT:
Currently I'm using a neovim only plugin telescope.nvim which is very similar to fzf.vim, it has the command :Telescope old_files. And it can use the fzf algorithm as a sorting algorithm in the backend (which is currently recommended over the default sorter).
It looks a bit nicer, but can be a bit slower depending on the context. It is not as mature as fzf, but to me easier to customize, it is all lua script.
If you are a neovim only user, definitely worth checking out imho.

Upvotes: 9

nenchev
nenchev

Reputation: 2087

Use :bro ol then press the number that corresponds to the file you want to open.

Upvotes: 15

IvanDi
IvanDi

Reputation: 147

Also you can go back with ctrl+O.

Upvotes: 1

Bryan Perez
Bryan Perez

Reputation: 61

:ls to list recent files with buffer number on left-hand column.

Then do :b{buffer-number} to jump there.

Example: :ls shows list of files. I want to jump to third-last file I visited. :b3 will take me there.

For faster searching, map :ls to something, e.g. <Leader>. in your .vimrc file.

Upvotes: 2

Alexx Roche
Alexx Roche

Reputation: 3249

You might be able to access the list from the command line with:

grep '^>' ~/.viminfo|cut -c3-|sed 's,~,'"$HOME"','

Explanation:

grep '^>' ~/.viminfo  #find the list of recent files
cut -c3-              #remove the first 2 characters
sed 's,~,'"$HOME"','  #replace ~ with absolute path

You could have a bash alias if you use this regularly

alias vim_mru="grep '^>' ~/.viminfo|cut -c3-|sed 's,~,'\"$HOME\"','"

Upvotes: 3

sarnold
sarnold

Reputation: 104110

At least terminal vim stores the previous ten files into ~/.viminfo in the filemarks section. You can use '0, '1, '2, ... '9 to jump among them.

(Probably only useful for '0 to get back to the last file you were editing, unless your memory is stronger than mine.)

You can also use the :browse oldfiles command to get a menu with numbers.

Upvotes: 264

Alexey
Alexey

Reputation: 9457

There is an Swiss knife of file switching CtrlP plugin, which is also part of janus distributive. It has :CtrlPMRU command with smart lookup among recently used files.

Note: CtrlP maintains its own list of most recent used files in g:ctrlp_cache_dir."mru/cache.txt". It is not reusing viminfo (set viminfo?) which contains a list of file marks. This is useful if you want to clear this list.

Upvotes: 11

andor kesselman
andor kesselman

Reputation: 1179

The best way that I use is 

:browse oldfiles

Easiest way on vim.

Upvotes: 75

Krzysztof Adamski
Krzysztof Adamski

Reputation: 2079

One more plugin that let's you choose file from the list of last modified ones is staritfy. It replaces your start screen with a list of most recently modified files. You can always open this page later using :Startify command.

Upvotes: 1

Andy Ray
Andy Ray

Reputation: 32076

The CtrlP plugin lets you search through your recently used files as well as files in the current directory with this command:

nnoremap <c-p> :CtrlPMixed<cr>

This saves you the hassle of having to deal with built in Vim commands and the MRU plugin, neither of which let you do fuzzy file searching, which is critical when working on larger projects.

Upvotes: 5

Edward J Beckett
Edward J Beckett

Reputation: 5140

Very late answer here ... expounding on @sarnolds answer - You can view the file history with the oldfiles command @see :h oldfiles or :h viminfo

:oldfiles

Furthermore, you can have fine-grained file management with views and sessions ... @see :h mkview and :h mksession for specifics ...

Upvotes: 22

user886333
user886333

Reputation: 29

As seen in the comments here (http://stackoverflow.com/questions/571955/undo-close-tab-in-vim), your file is probably still open in a buffer: 

:ls " get the buffer number
:tabnew +Nbuf " where N is the buffer number

For example you can reopen the third buffer in a new tab (use :e instead if you don't use tabs):

:tabnew +3buf

Upvotes: 2

thegeek
thegeek

Reputation: 2458

MRU has lot of features as explained here: http://www.thegeekstuff.com/2009/08/vim-editor-how-to-setup-most-recently-used-documents-features-using-mru-plugin/

Upvotes: 5

pmr
pmr

Reputation: 59841

There is mru.vim, which adds the :MRU command.

Upvotes: 46

Related Questions