CODEWITHSUNDEEP
batch-file
Piotr Fraczek
Piotr Fraczek

Reputation: 43

Speed up batch code

Can you advice what else I can do for speeding up my batch, please? Works quite well apart takes ages to finish :)

Sorry for this text but I'm not able to post my question due to the message 'it looks like your post is mostly code bla bla bla. Admin- can you turn this verification OFF!!!

 @echo off
c:
cd \
pushd \\ftp\ftp$

cls
echo ________________________________________________________________
echo.

color f9
:WPIS
set /p moje=Please enter required LOGIN NAME: 
if exist "\\ftp\ftp\Transfer\%moje%" echo USER ALREADY EXIST TRY ANOTHER ONE && GOTO WPIS

:KOD
set mojep=%random%%random%%random%

setlocal enabledelayedexpansion

set input=default2015.Archive
set output2=%moje%.Archive2
set output1=%moje%.Archive1
set output=%moje%.Archive
set text2searchfor=default2015

set password2searchfor=szukajpassword

set folder2search=F:\\Transfer\\default2015
set newfolder=F:\\Transfer\\%moje%

del %output1%
cls
echo Wait....
for /F "tokens=*" %%f in ('type %input%') do (
set line=%%f
if "!line!"=="%text2searchfor%" (
set NAME=%moje%
echo !NAME!>> %output2%
) else (
echo !line!>> %output2%
)
)


for /F "tokens=*" %%f in ('type %output2%') do (
set line=%%f
if "!line!"=="%folder2search%" (
set NAME=%newfolder%
echo !NAME!>> %output1%
) else (
echo !line!>> %output1%
)
)

for /F "tokens=*" %%f in ('type %output1%') do (
set line=%%f
if "!line!"=="%password2searchfor%" (
set NAME=%mojep%
echo !NAME!>> %output%
) else (
echo !line!>> %output%
)
)

del %output1%
del %output2%

pushd \\ftp\ftp\Transfer\
md %moje%
popd \\ftp\ftp\Transfer\
popd \\ftp\ftp$

...

Upvotes: 1

Views: 2325

Answers (2)

Aacini
Aacini

Reputation: 67216

Try this:

@echo off
c:
cd \
pushd \\ftp\ftp$

cls
echo ________________________________________________________________
echo.

color f9
:WPIS
set /p moje=Please enter required LOGIN NAME: 
if exist "\\ftp\ftp\Transfer\%moje%" echo USER ALREADY EXIST TRY ANOTHER ONE && GOTO WPIS

:KOD
set mojep=%random%%random%%random%

setlocal

set input=default2015.Archive
set output2=%moje%.Archive2
set output1=%moje%.Archive1
set output=%moje%.Archive
set text2searchfor=default2015

set password2searchfor=szukajpassword

set folder2search=F:\\Transfer\\default2015
set newfolder=F:\\Transfer\\%moje%

cls
echo Wait....
(for /F "delims=" %%f in (%input%) do (
   if "%%f"=="%text2searchfor%" (
      echo %moje%
   ) else (
      echo %%f
   )
)) > %output2%


(for /F "delims=" %%f in (%output2%) do (
   if "%%f"=="%folder2search%" (
      echo %newfolder%
   ) else (
      echo %%f
   )
)) > %output1%

(for /F "delims=" %%f in (%output1%) do (
   if "%%f"=="%password2searchfor%" (
      echo %mojep%
   ) else (
      echo %%f
   )
)) > %output%

del %output1%
del %output2%

pushd \\ftp\ftp\Transfer\
md %moje%
popd \\ftp\ftp\Transfer\
popd \\ftp\ftp$

If more speed is needed, a much faster solution may be written via a Batch-JScript hybrid script.

Upvotes: 2

foxidrive
foxidrive

Reputation: 41244

This uses a native Windows batch script called Jrepl.bat (by dbenham)
- download from: https://www.dropbox.com/s/4otci4d4s8x5ni4/Jrepl.bat
and it can also be found here: http://www.dostips.com/forum/viewtopic.php?f=3&t=6044

It is significantly faster for large files than plain vanilla for loops.

This assumes that your strings to be replaced are not embedded in any other lines, and just occur by themselves.

As you are changing the directory, placing jrepl.bat on the system path is wise so the script can find it, or hard code the path to jrepl.bat 

@echo off
cd /d c:\
pushd \\ftp\ftp$

cls
echo ________________________________________________________________
echo.

color f9
:WPIS
set /p moje=Please enter required LOGIN NAME:
if exist "\\ftp\ftp\Transfer\%moje%" echo USER ALREADY EXIST TRY ANOTHER ONE && GOTO WPIS

:KOD
set mojep=%random%%random%%random%

setlocal enabledelayedexpansion

set input=default2015.Archive
set output2=%moje%.Archive2
set output1=%moje%.Archive1
set output=%moje%.Archive
set text2searchfor=default2015

set password2searchfor=szukajpassword

set folder2search=F:\\Transfer\\default2015
set newfolder=F:\\Transfer\\%moje%


cls
echo Wait....

call jrepl "%text2searchfor%"      "%moje%"      /L /f %input%  /o %output%
call jrepl "%folder2search%"       "%newfolder%" /L /f %output% /o -
call jrepl "%password2searchfor%"  "%mojep%"     /L /f %output% /o -


pushd \\ftp\ftp\Transfer\
md %moje%
popd \\ftp\ftp\Transfer\
popd \\ftp\ftp$

Upvotes: 1

Related Questions