Not declared in this scope - Arduino

Question

I'm having a problem when I try this code I've made:

int ledStart = 30;

boolean commonHigh = true;

void setup() {
   Serial.begin(115200);
   SetTimer(0, 0, 10); // 10 seconds
   StartTimer();

   for (int i =0;i<9;++i) {
     pinMode (i, OUTPUT);
   }
   pinMode(9, INPUT);
}

int counter = 0;
bool go_by_switch = true;
int last_input_value = LOW;

void loop() {
    // put your main code here, to run repeatedly:
  
    number++;
    delay(1000);

    if(number>9)
        number=0; // If number is bigger than 9, then number is 0
}

//                0                   6
// pins           A   B  C  D  E   F  G
int ledpins[] = {12, 10, 7, 4, 2, 13, 8};
int pincnt = 7; 
int number = 0;

int sevenseg[10][7] = {
// A, B, C, D, E, F, G
{1, 1, 1, 1, 1, 1, 0}, // A-F shall light. G shall not light. 
{0, 1, 1, 0, 0, 0, 0}, // A shall not light. B and C shall light.

/*0*/
/*1*/
/*2*/
/*3*/
/*4*/
/*5*/
/*6*/
/*7*/
/*8*/

{1, 1, 1, 1, 1, 1, 1, 1}

if(go_by_switch) {
    int switch_input_value = digitalRead(9);
    if(last_input_value == LOW && switch_input_value == HIGH) {
        counter = (counter + 1) % 10;
    }
  
    last_input_value = switch_input_value;
} 
else {
    delay(500);
    counter = (counter + 1) % 10;
}

writeNumber(counter);
}
  
for (int p=0; p<pincnt; p++) { 
    pinMode (ledpins[P], OUTPUT);
    //It will count from 0 to smaller than 7. {12, 10, 7, 4, 2, 13, 8}; It will count from 0 to smaller than 7.
                                       //   0   1  2  3  4   5  6
             
    digitalWrite(ledpins[P], LOW);
}
                                        
for (int x=0; x<pincnt; x++); { //x is smaller than 7. The point is to bring out one of the patterns that will show on the display 

    if (sevenseg[number][x]) // sevenseg = 7-segment display
        digitalWrite (ledpins[x], HIGH); // If it is 1, then there will be light.
    else 
        digitalWrite (ledpins[x], LOW); // If it is 0, then there will not be light.


//   A
//F     B
//   G
//E     C
//   D

The error message I get is:

_28.10.2015.ino: In function 'void setup()':

_28.10.2015.ino:7:20: error: 'SetTimer' was not declared in this scope

_28.10.2015.ino:8:14: error: 'StartTimer' was not declared in this scope

_28.10.2015.ino: In function 'void loop()':

_28.10.2015.ino:22:1: error: 'number' was not declared in this scope

_28.10.2015.ino: At global scope:

_28.10.2015.ino:52:1: error: expected '}' before 'if'

_28.10.2015.ino:52:1: error: too many initializers for 'int [7]'

_28.10.2015.ino:52:1: error: expected ',' or ';' before 'if'

Feil ved kompilering.

(Feil ved kompilering=Errors at compile(Norwegian)

Answer 1

There are quite a few issues with this code.

• One of the first things that I notice is that you close out your loop() function with }, then you proceed to write more code that doesn't belong to any function at all.
• Also, as @Raul points out, you define an array sevenseg[][], but you do not end the statement with a semicolon.
• Your last for() loop is missing its closing brace, }.
• Your last for() loop has a semicolon before the opening brace. It shouldn't be there.
• You use the variable number in your loop() function, but you define what number is after you use it. You have to define a variable before you use it.
• You call SetTimer() and StartTimer() in your setup() function, but those functions are not defined. That's because either 1, you have not included the library where those functions are defined or 2, you did not define those functions yourself. If your issue is 1, then I assume you intended to use #include <SimpleTimer.h>. Note that you also have to install that library. The instructions on how to download it and add it to your Arduino libraries are here. Finally, you have to create a timer object like this: SimpleTimer timer; and then you can call the function like this, timer.SetTimer(your-parameters-here);.

There are probably other things that I have missed, but that should give you a starting point. It looks like you have created a lot of code without testing to see if any of it worked. I would recommend taking this a step at a time... code one logical block and see if it works before you move on to coding your next idea. It may seem like it takes more time but, in the end, it is usually a much faster way to program.

Another suggestion that I would make is to define variables within the function in which you use them. Making all of your variables "global" like you have done is not a good way to write code. For example:

void loop()
{
    static int number = 0;

    number++;
    delay(1000);

    if (number > 9)
    {
        number = 0;
    }
}

Note the use of the keyword static. This will ensure that the value stored in number will not go away when the function ends. In other words, the value will still be there the next time the loop() function is called.

Finally, if I had to guess at what you were trying to accomplish, I would think your code should look a little more like this. It appears as though you were trying out different things so I left a number of code snippets in there from your original code that don't actually do anything:

void setup() {
    Serial.begin(115200);

    for (int i = 0; i < 9; ++i) 
    {
        pinMode (i, OUTPUT);
    }
    pinMode(9, INPUT);
}

void loop() {
    static int counter = 0;
    static int last_input_value = LOW;
    static bool go_by_switch = true;

    if(go_by_switch) 
    {
        int switch_input_value = digitalRead(9);
        if(last_input_value == LOW && switch_input_value == HIGH) 
        {
            counter = (counter + 1) % 10;
        }

        last_input_value = switch_input_value;
    } 
    else 
    {
        delay(500);
        counter = (counter + 1) % 10;
    }

    writeNumber(counter);
}

void writeNumber (int count)
{
    #define PIN_COUNT           7
    #define NUM_OF_SEGMENTS     7
    #define NUM_OF_NUMBERS      10

                         //                0                   6
                         // pins           A   B  C  D  E   F  G
    static const int ledpins[PIN_COUNT] = {12, 10, 7, 4, 2, 13, 8};
    static const int sevenseg[NUM_OF_NUMBERS][NUM_OF_SEGMENTS] =
    {
      // A   B   C   D   E   F   G
        {1,  1,  1,  1,  1,  1,  0},  //0
        {0,  1,  1,  0,  0,  0,  0},  //1
        {1,  1,  0,  1,  1,  0,  1},  //2
        {1,  1,  1,  1,  0,  0,  1},  //3
        {0,  1,  1,  0,  0,  1,  1},  //4
        {1,  0,  1,  1,  0,  1,  1},  //5
        {1,  0,  1,  1,  1,  1,  1},  //6
        {1,  1,  1,  0,  0,  0,  0},  //7
        {1,  1,  1,  1,  1,  1,  1},  //8
        {1,  1,  1,  1,  0,  1,  1},  //9
    };
    static int number = 0;
    int i;

    number++;
    delay(1000);

    if(number >= NUM_OF_NUMBERS)
    {
        number = 0;
    }

    /* Clear all segments of the 7-segment display. */
    for (i = 0; i < PIN_COUNT; i++) 
    { 
        pinMode (ledpins[i], OUTPUT);
        digitalWrite(ledpins[i], LOW);
    }

    /* Set the 7-segment display with the current number. */
    for (i = 0; i < PIN_COUNT; i++) 
    {
        if (sevenseg[number][i]) // sevenseg = 7-segment display
            digitalWrite (ledpins[i], HIGH); // If it is 1, then there will be light.
        else 
            digitalWrite (ledpins[i], LOW); // If it is 0, then there will not be light.
    }
}

Answer 2

The problem is that you are not declaring these functions that you are getting errors, neither the "number" variable. You need to declare them, like:

int number;

void StartTimer( ) { // function code; }

Or include a ".h" that contain these functions, like @Neil Locketz said.