CODEWITHSUNDEEP
xmlxslt-2.0saxon
user3813234
user3813234

Reputation: 1682

xslt remove duplicate elements

I am trying to remove elements with the same href attribute form this file:

<?xml version="1.0" encoding="UTF-8"?>
<images>
    <item id="d1e152_1" href="Pic/104764.jpg" media-type="image/jpeg"/>
    <item id="d1e163_2" href="Pic/104764.jpg" media-type="image/jpeg"/>
    <item id="d1e174_3" href="Pic/104764.jpg" media-type="image/jpeg"/>
    <item id="d1e218_4" href="Pic/104763.jpg" media-type="image/jpeg"/>
    <item id="d1e349_5" href="Pic/110001.tif" media-type="image/tif"/>
    <item id="d1e681_6" href="Pic/199201.tif" media-type="image/tif"/>
    <item id="d1e688_7" href="Pic/124566.tif" media-type="image/tif"/>
</images>

using this xslt 2.0 stylesheet

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions" exclude-result-prefixes="fn xs fo">

<xsl:output method="xml"/>

<xsl:strip-space elements="*"/>

<xsl:template match="/images">
<new_images>
    <xsl:apply-templates/>
    </new_images>
</xsl:template>

<xsl:template match="item">
<xsl:for-each-group select="." group-by="@href">
    <xsl:copy-of select="current-group()[1]"/>
</xsl:for-each-group>
</xsl:template>

</xsl:stylesheet>

Expected result here:

<?xml version="1.0" encoding="UTF-8"?>
<new_images>
    <item id="d1e152_1" href="Pic/104764.jpg" media-type="image/jpeg"/>
    <item id="d1e218_4" href="Pic/104763.jpg" media-type="image/jpeg"/>
    <item id="d1e349_5" href="Pic/110001.tif" media-type="image/tif"/>
    <item id="d1e681_6" href="Pic/199201.tif" media-type="image/tif"/>
    <item id="d1e688_7" href="Pic/124566.tif" media-type="image/tif"/>
</new_images>

Why doesnt it work? I still have all duplicates in the generated xsl file.

Upvotes: 2

Views: 3324

Answers (2)

Dimitre Novatchev
Dimitre Novatchev

Reputation: 243459

This XSLT 1.0 solution is shorter and not slower:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:key name="kByHref" match="item" use="@href"/>

  <xsl:template match="/*">
    <new_images>
      <xsl:copy-of select=
      "*[generate-id() = generate-id(key('kByHref', @href)[1])]"/>
    </new_images>
  </xsl:template>
</xsl:stylesheet>

Upvotes: 1

user3813234
user3813234

Reputation: 1682

I got it.... happens to me all the time... got to put the for-each-group in the template for /images...

Updated XSLT 2.0...

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions" exclude-result-prefixes="fn xs fo">

  <xsl:output method="xml"/>

  <xsl:strip-space elements="*"/>

  <xsl:template match="/images">
    <new_images>
      <xsl:for-each-group select="item" group-by="@href">
        <xsl:copy-of select="current-group()[1]"/>
      </xsl:for-each-group>
    </new_images>
  </xsl:template>

</xsl:stylesheet>

Upvotes: 2

Related Questions