How to close a programm in Erlang with WxWidgets?

Question

I have a problem to close a program in Erlang. I use wxWidgets.

-module(g).
-compile(export_all).
-define(height, 500).
-define(width, 500).  
-include_lib("wx/include/wx.hrl").
-define(EXIT,?wxID_EXIT).

init() ->
    start().

start() ->
    Wx = wx:new(),
    Frame = wxFrame:new(Wx, -1, "Line", [{size, {?height, ?width}}]),   
    setup(Frame),
    wxFrame:show(Frame),
    loop(Frame).

setup(Frame) ->
    menuBar(Frame),
    wxFrame:connect(Frame, close_window).

menuBar(Frame) ->
    MenuBar = wxMenuBar:new(),
    File = wxMenu:new(),
    wxMenuBar:append(MenuBar,File,"&Fichier"),
    wxFrame:setMenuBar(Frame,MenuBar),  
    Quit = wxMenuItem:new ([{id,400},{text, "&Quit"}]),
    wxMenu:append (File, Quit).

loop(Frame) ->
    receive
        #wx{event=#wxCommand{type=close_window}} ->
            io:format("quit icon"),
            wxWindow:close(Frame,[]);       

        #wx{id=?EXIT, event=#wxCommand{type=command_menu_selected}} ->
            io:format("quit file menu"),
            wxWindow:close(Frame,[])
    end.

But the program doesn't close; neither the quit icon or Quit from the menu do anything.

Answer 1

In addition to Michael's answer regarding using connect/3 to listen for menu commands, nearly any frame will require a few standard event connections to behave the way you expect them to on closing in addition to whatever specific things you have going on. Note that this is connecting to the close_window event and using the option {skip, true}. This is so the signal doesn't stop propagating before it hits the part of Wx that will handle it the way you expect (one click to close) instead of requiring two clicks to close the frame on some platforms.

The basic skeleton often looks like this:

init(Args) ->
    Wx = wx:new(),
    Frame = wxFrame:new(Wx, ?wxID_ANY, ""),

    % Generate whatever state the process represents
    State = some_state_initializer(Args),

    % Go through the steps to create your widget layout, etc.
    WidgetReferences = make_ui(Frame),

    % The standardish connects nearly any frame will need.
    ok = wxFrame:connect(Frame, close_window, [{skip, true}]),
    ok = wxFrame:connect(Frame, command_button_clicked),
    ok = wxFrame:connect(Frame, command_menu_selected),
    % Add more connects here depending on what you need.

    % Adjust the frame size and location, if necessary
    Pos = initial_position(Args),
    Size = initial_size(Args),
    ok = wxFrame:move(Frame, Pos),
    ok = wxFrame:setSize(Frame, Size),

    wxFrame:show(Frame),

    % Optional step to add this frame to a UI state manager if you're
    % writing a multi-window application.
    ok = gui_manager:add_live(self()),

    % Required return for wx_object behavior
    {Frame, State}.

Digressing a bit from the original, but strongly related...

Many wxWidgets application have something very similar to this, customized as necessary not by writing all that out again, but by defining your own callback module and passing it in as an argument:

init({Mod, Args}) ->
    % ...
    PartialState = blank_state([{mod, Mod}, {frame, Frame}, {wx, Wx}]),
    State = Mod:finalize(PartialState, Args),

Where blank_state/1 accepts a proplist and returns whatever the actual data structure will be later (usually a record at this level, that looks something like #s{mod, frame, wx, widgets, data}), and Mod:finalize/2 takes the incomplete state and the initial args and returns a completed GUI frame plus whatever program state it is supposed to manage -- in particular the widgets data structure that carries references to any GUI elements you will need to listen for, match on, or manipulate later.

Later on you have some very basic generic handlers all frames might need to deal with, and pass any other messages through to the specific Mod:

handle_call(Message, From, State = #s{mod = Mod}) ->
    Mod:handle_call(Message, From, State).

handle_cast(blit, State) ->
    {ok, NewState} = do_blit(State),
    {noreply, NewState};
handle_cast(show, State) ->
    ok = do_show(State),
    {noreply, State};
handle_cast(Message, State = #s{mod = Mod}) ->
    Mod:handle_cast(Message, State).

In this case do_blit/1 winds up calling Mod:blit/1 in the callback module which rebuilds and refreshes the GUI, rebuilding it from zero by calling a function that does that within wx:batch/1 to make it appear instant to the user:

blit(State) ->
    wx:batch(fun() -> freshen_ui(State) end).

If you have a lot of elements to change in the GUI at once, blitting is far smoother and faster from the user's perspective than incrementally shuffling things around or hiding/showing elements as you go -- and is much more certain to feel the same across platforms and various computer speeds and userland loads (some Wx backends give a lot of flicker or intermediate display weirdness otherwise).

The do_show/1 function usually looks something like

do_show(#s{frame = Frame}) ->
    ok = wxFrame:raise(Frame),
    wxFrame:requestUserAttention(Frame).

(I have been meaning to write a basic "here is one way to structure a multi-window wxErlang application" tutorial/example but just haven't gotten around to it, so a lot of details are missing here but you'll stumble on them on your own after writing a couple of programs.)

Answer 2

You're almost there, but there's a few mistakes.

First, there's never any event being generated for your quit selection on your mention, you need to use connect again, like this:

Quit = wxMenuItem:new ([{id,400},{text, "&Quit"}]),
wxFrame:connect(Frame, command_menu_selected),

Now you have an event for each of the quit methods, but neither of them is working still.

The event for your quit icon isn't matching because you have the wrong event type in your pattern match, and the event for the menu quit selection isn't matching because you're looking for an ID of ?EXIT, which is defined as ?wxID_EDIT, which is defined as.. well clearly not 400, the ID you used when you created your quit menu item. So your receive clause needs to be changed to something like this:

receive
    #wx{event=#wxClose{type=close_window}} ->
        io:format("quit icon"),
        wxFrame:destroy(Frame);
    #wx{id=400, event=#wxCommand{type=command_menu_selected}} ->
        io:format("quit file menu"),
        wxFrame:destroy(Frame)
    end.