CODEWITHSUNDEEP
vimscriptingvi
btw
btw

Reputation: 483

What is the easiest way to swap occurrences of two strings in Vim?

What is the easiest way to replace all occurrences of string_a with string_b while at the same time changing anything that was already string_b into string_a? My current method is as follows:

:s/string_a/string_c/g  
:s/string_b/string_a/g  
:s/string_c/string_b/g

Although this works, it requires extra typing and seems inefficient. Does anybody know of a better way to do this?

Upvotes: 48

Views: 11015

Answers (6)

moorhuhn
moorhuhn

Reputation: 341

Here is an example how to swap 2 strings separated by space bar within one line. One can use:

:'a,'bs/\(.*\s\)\(.*$\)/ \2 \1/g

where 'a,'b defines section where this command is applied
      .*\s specifies string from begin of the line until space bar (\s)
      .*$  specifies the section until the end of the line
      \2 \1  in substitution use first section 2 and then section 1

Upvotes: 0

ptgamr
ptgamr

Reputation: 594

Here is how I swap two words skip & limit:

%s/skip/xxxxx/g | %s/limit/skip/g | %s/xxxxx/limit/g

Pretty sure someone could turn it into a shorter command which accepts two arguments.

Upvotes: 6

Sebi
Sebi

Reputation: 9023

You can do it with a single command as shown in my code below:

:%s/\<\(string_a\|string_b\)\>/\=strpart("string_bstring_a", 8 * ("string_b" == submatch(0)), 8)/g

Upvotes: 1

Ingo Karkat
Ingo Karkat

Reputation: 172590

The swapstrings plugin provides a handy command for this:

:SwapStrings string_a string_b

Upvotes: 3

Peter Rincker
Peter Rincker

Reputation: 45117

You can do this easily with Tim Pope's Abolish plugin

:%S/{transmit,receive}/{receive,transmit}

Upvotes: 18

Brian Carper
Brian Carper

Reputation: 72926

I'd do it like this:

:%s/\v(foo|bar)/\={'foo':'bar','bar':'foo'}[submatch(0)]/g

But that's too much typing, so I'd do this:

function! Mirror(dict)
    for [key, value] in items(a:dict)
        let a:dict[value] = key
    endfor
    return a:dict
endfunction

function! S(number)
    return submatch(a:number)
endfunction

:%s/\v(foo|bar)/\=Mirror({'foo':'bar'})[S(0)]/g

But that still requires typing foo and bar twice, so I'd do something like this:

function! SwapWords(dict, ...)
    let words = keys(a:dict) + values(a:dict)
    let words = map(words, 'escape(v:val, "|")')
    if(a:0 == 1)
        let delimiter = a:1
    else
        let delimiter = '/'
    endif
    let pattern = '\v(' . join(words, '|') . ')'
    exe '%s' . delimiter . pattern . delimiter
        \ . '\=' . string(Mirror(a:dict)) . '[S(0)]'
        \ . delimiter . 'g'
endfunction

:call SwapWords({'foo':'bar'})

If one of your words contains a /, you have to pass in a delimiter which you know none of your words contains, .e.g

:call SwapWords({'foo/bar':'foo/baz'}, '@')

This also has the benefit of being able to swap multiple pairs of words at once.

:call SwapWords({'foo':'bar', 'baz':'quux'})

Upvotes: 27

Related Questions