CODEWITHSUNDEEP
bashawk
Mark
Mark

Reputation: 1554

Finding Contiguous Ranges

I would like to find the contiguous ranges given a set of dates by day

given the following sample

2016-01-01
2016-01-02
2016-01-03
2016-01-04
2016-01-05
2016-01-06
2016-01-08
2016-01-09
2016-01-10
2016-01-11
2016-01-12
2016-01-15
2016-01-16
2016-01-17
2016-01-20
2016-01-21
2016-01-30
2016-01-31
2016-02-01

I expect the following result

2016-01-01-2016-01-06
2016-01-08-2016-01-12
2016-01-15-2016-01-17
2016-01-20-2016-01-21
2016-01-30-2016-01-31
2016-02-01-2016-02-01

I have already came across this question which is almost the opposite of what I want but with integers. I have formulated the following which works with integers.

awk 'NR==1 {l=$1; n=$1} {if ($1==n){n=$1+1} else{print l"-"n-1; l=$1 ;n=$1+1} } END {print l"-"$1}' file.txt

Upvotes: 0

Views: 145

Answers (3)

Ed Morton
Ed Morton

Reputation: 203334

With GNU awk for mktime():

$ cat tst.awk
BEGIN { FS=OFS="-" }
{ currSecs = mktime( $1" "$2" "$3" 0 0 0" ) }
(currSecs - prevSecs) > (24*60*60) {
    if (NR>1) {
        print startDate, prevDate
    }
    startDate = $0
}
{ prevSecs = currSecs; prevDate = $0 }
END { print startDate, prevDate }

$ awk -f tst.awk file
2016-01-01-2016-01-06
2016-01-08-2016-01-12
2016-01-15-2016-01-17
2016-01-20-2016-01-21
2016-01-30-2016-02-01

With any awk if you don't care about ranges restarting when months change (as apparent in your expected output and the comment under your question):

$ cat tst.awk
BEGIN { FS=OFS="-" }
{ currYrMth = $1 FS $2; currDay = $3 }
(currYrMth != prevYrMth) || ((currDay - prevDay) > 1) {
    if (NR>1) {
        print startDate, prevDate
    }
    startDate = $0
}
{ prevYrMth = currYrMth; prevDay = currDay; prevDate = $0 }
END { print startDate, prevDate }

$ awk -f tst.awk file
2016-01-01-2016-01-06
2016-01-08-2016-01-12
2016-01-15-2016-01-17
2016-01-20-2016-01-21
2016-01-30-2016-01-31
2016-02-01-2016-02-01

Upvotes: 1

jijinp
jijinp

Reputation: 2662

gawk:

#!/bin/awk -f
BEGIN{
        FS="-"
}
{
        a[NR]=mktime($1" "$2" "$3" 0 0 0")
        b[NR]=$2;
        if ( (a[NR-1]+86400) != a[NR] || b[NR-1]!=b[NR] ) {
                if(NR!=1){
                        print s" - "strftime("%Y-%m-%d",a[NR-1])
                };
                s=$0
        }
}
END{
        print s" - "$0
}

Create array a with index NR and value as epochtime derived from $0 using awk time function mktime.

Array b with index NR and value as the month in $2 if either epoch time from last line + 86400 ( +1 day) is not equal to epoch time in current line or month in previous line and current line differs, except for first line, print value in s" - "strftime("%Y-%m-%d",a[NR-1] and reassign s which is the start date with $0

END: Print the last start time s and last line

Upvotes: 0

tripleee
tripleee

Reputation: 189377

If you have GNU Awk you can use its time functions.

gawk -F - 'NR==1 || $1 "-" $2 "-" $3 != following {
    if (following != "") print start "-" latest;
    start = $1 "-" $2 "-" $3
    this = mktime($1 " " $2 " " $3 " 0 0 0")
  }
  {
    this += 24*60*60
    following = strftime("%F", this)
    latest = $1 "-" $2 "-" $3 }
  END { if (start != latest) print start "-" latest }' filename

Unit ranges will print like "2016-04-15-2016-04-15" which is a bit of a wart, but easy to fix if you need to. Also the END block has a bug in this case, but again, this should at least get you started.

Upvotes: 0

Related Questions