CODEWITHSUNDEEP
tcl
Bryan
Bryan

Reputation: 339

Count number of unique element in a list

Say I have a list, a b c b b d e e f …, and I don't know how many different kind of elements are in there.

How do I count the number of each unique element and print them out? Output would looks like:

a: 32
b: 12
c: 6
…

Upvotes: 2

Views: 9083

Answers (4)

Suman Prasad
Suman Prasad

Reputation: 11

It can be easily done using lsearch and llength.
Lets say your list is {a c a c s a a c a} then,

set tempList {a c a c s a a c a}  
puts "c : [llength [lsearch -all $tempList  c]]"  
puts "a : [llength [lsearch -all $tempList  a]]"  
puts "d : [llength [lsearch -all $tempList  d]]"

Output :
c : 3
a : 5
d : 0

Explanation : lsearch -all, will return all the index of matching element and this list of index is returned to llength which will count length of the list.

Upvotes: 1

Peter Lewerin
Peter Lewerin

Reputation: 13252

The dict or array solution is the best one and should be preferred. Another way that works on a sorted list of tokens is to match contiguous regions of non-blank tokens.

% regexp -all -inline {(\S+)(?:\s+\1)*} {a a b b b c d d}
{a a} a {b b b} b c c {d d} d

The result is an even-sized list of alternately matched regions of tokens and the token matched in the region. This can be used to print a frequency report for the tokens in the list in list.

foreach {a b} [regexp -all -inline {(\S+)(?:\s+\1)*} [lsort $list]] {
    puts "$b: [llength $a]"
}

Note the limitation that the tokens cannot contain blanks. This can be overcome, but it's simpler to use the array / dict solution which only requires the tokens to be valid list elements.

Documentation: foreach, llength, lsort, puts, Syntax of Tcl regular expressions, regexp

Upvotes: 0

toxic_boi_8041
toxic_boi_8041

Reputation: 1482

Try this if you have 8.4 or older version of TCL,

set lst "a a a a b b b c c c d d a a a f f f f f s s s s"

set unique [lsort -unique $lst]    
foreach f $unique {
    set cnt 0
    foreach item $lst {
        if {$item == $f} {
            incr cnt
        }
    }
    puts "$f :: $cnt"
}

Gives Output Like,

% tclsh main.tcl
a :: 7
b :: 3                                                                                                                                                              
c :: 3
d :: 2                                                                                                                                                              
f :: 5
s :: 4

Upvotes: 1

Donal Fellows
Donal Fellows

Reputation: 137567

You have to count them up. This isn't too hard with an array or dictionary of counters. I'll use a dictionary since then they'll be printed in order of first occurrence. (With an array, you'd get a “random” order or you'd have to sort them.)

set counters {}
foreach item $list {
    dict incr counters $item
}
dict for {item count} $counters {
    puts "${item}: $count"
}

Upvotes: 6

Related Questions