CODEWITHSUNDEEP
vb.netlistduplicates
Mech_Engineer
Mech_Engineer

Reputation: 555

Remove duplicates from List(Of T)

How can I remove my duplicates in the List(Of String)? I was under the assumption that it could work with List(Of T).Distinct, but my result says otherwise. What am I doing wrong? Or what do I have to change to remove the duplicate items in the List(Of T)?

I have read something on the worldwide web about hash something, but I don't think that is really necessary.

This is my code where the list is generated (works with Autodesk Inventor).

Private Function CountCylinders(ByVal oDef As AssemblyComponentDefinition) As Integer

    ' Lets list all cylinder segments found in the assembly
    ' we will need the document name to do this.
    ' the initial value is nothing, if, after counting
    ' this is still the case, there are no cylinders.
    Dim oList As New List(Of String)

    ' Loop through all of the occurences found in the assembly
    For Each oOccurrence As ComponentOccurrence In oDef.Occurrences

        ' Get the occurence document
        Dim oOccurenceDocument As Document
        oOccurenceDocument = oOccurrence.Definition.Document

        ' Check if the occurence document name contains cylinder
        If oOccurenceDocument.FullFileName.Contains("Cylinder") Then
            ' Get the cylinder filename
            Dim oCylinder As String
            oCylinder = oOccurenceDocument.FullFileName

            ' Get the filename w/o extension
            oCylinder = IO.Path.GetFileNameWithoutExtension(oCylinder)

            ' Remove the segment mark.
            oCylinder = oCylinder.Remove(oCylinder.LastIndexOf("_"), oCylinder.Length - oCylinder.LastIndexOf("_"))

            oList.Add(oCylinder)
            Debug.Print("add : " & oCylinder)
        End If
    Next

    ' Delete the duplicates in the list
    oList.Distinct()

    ' TODO: can be removed.
    Debug.Print("Total number of cylinders = " & oList.Count)

    ' Return the number of cylinders
    CountCylinders = oList.Count

End Function

Here is my debug output from the code:

add : Cylinder_1
add : Cylinder_2
add : Cylinder_2
add : Cylinder_2
add : Cylinder_2
add : Cylinder_2
add : Cylinder_7
Total number of cylinders = 7

Upvotes: 4

Views: 21315

Answers (3)

Zeus Paez
Zeus Paez

Reputation: 31

Imports System.Linq

...

Dim oList As New List(Of String)
oList.Add("My Cylinder")
oList = oList.Distinct.ToList()

It's necessary to include System.Linq.

Upvotes: 2

Mark
Mark

Reputation: 188

This is the answer you're looking for thanks to dotnetperls.com VB.NET Remove Duplicates From List

ListOfString.Distinct().ToList

Upvotes: 10

Johann Camboly
Johann Camboly

Reputation: 40

Function RemoveDuplicate(ByVal TheList As List(Of String)) As List(Of String)
    Dim Result As New List(Of String)

    Dim Exist As Boolean = False
    For Each ElementString As String In TheList
        Exist = False
        For Each ElementStringInResult As String In Result
            If ElementString = ElementStringInResult Then
                Exist = True
                Exit For
            End If
        Next
        If Not Exist Then
            Result.Add(ElementString)
        End If
    Next

    Return Result
End Function

Upvotes: 1

Related Questions