CODEWITHSUNDEEP
regexperlfile
flop
flop

Reputation: 1

Perl: file search regex multiple infos in multiple lines

Hello I have this in a file, multiple lines and from them I want to be able to get the User name and the version he's using.

File

<W>2016-06-25 00:27:30.577 1 => <4:(-1)> Client version 1.2.10 (Win: 1.2.10)
<W>2016-06-25 00:27:30.635 1 => <4:[AAA] User1(1850)> Authenticated
<W>2016-06-25 00:27:30.635 1 => <2:(-1)> Client version 1.2.16 (Win: 1.2.16)
<W>2016-06-25 00:27:30.687 1 => <2:[AAA] User2(942)> Authenticated

Outpout wanted

4 : User1 : 1.2.10
2 : User2 : 1.2.16

So the datas for one client is on 2 lines.

I noticed that both lines have a match ID, in my example the user1 line match ID is 4: and 2: for the second user.

So I started with something like this, but don't really work as intended and creating a second read to find the second line in the entire file is too much / not optimized.

Perl Script

#!/usr/bin/perl
use strict;
use warnings;
my $file = 'mylogfile.log';
open (my $fl, '<:encoding(UTF-8)', $file)
        or die 'File not found';

while (my $row = <$fl>) {
        if ($row =~ m/\<(\d+).*\>\sclient\sversion\s(\d+.\d+.\d+)\s/i) {
                my $id = $1;
                my $vers = $2;
                while (my $row1 = <$fl>) {
                        if ($row1 =~ m/\<$id\:(.+)\(\d+\)\>/i) {
                                my $name = $1;
                                print "$id : $name : $vers\n";
                        }
                }
        }
}

If any perl guru have an idea, thanks! :-)

Upvotes: 0

Views: 70

Answers (3)

Chris Charley
Chris Charley

Reputation: 6633

Running your code gave me the result

4 : [AAA] User1 : 1.2.10

Your second regular expression is capturing the bracketed letters and the user name. This isn't what your desired output looks like.

The second while loop exhausts the remainder of the file. And, this isn't what you want to do.

Here is a program that will produce the output you want. (I created a file at the top of the program. You would not use this but instead, open your file 'mylogfile.log' just as you did in your code).

#!/usr/bin/perl
use strict;
use warnings;

open my $fh, '<', \<<EOF;
<W>2016-06-25 00:27:30.577 1 => <4:(-1)> Client version 1.2.10 (Win: 1.2.10)
<W>2016-06-25 00:27:30.635 1 => <4:[AAA] User1(1850)> Authenticated
<W>2016-06-25 00:27:30.635 1 => <2:(-1)> Client version 1.2.16 (Win: 1.2.16)
<W>2016-06-25 00:27:30.687 1 => <2:[AAA] User2(942)> Authenticated
EOF


while (<$fh>) {
    if (/<(\d+).+?Client version (\d+\.\d+\.\d+)/) {
        my ($id, $vers) = ($1, $2);

        # read next line and capture name
        if (<$fh> =~ /<$id\S+ ([^(]+)/) {
            my $name = $1;
            print join(" : ", $id, $name, $vers), "\n";
        }
    }
}

In my second regular expression, the piece, [^(]+, is called a negated class. It matches non 'left parens' (1 or more times). This matches "User1' and 'User2' in the line of the file.

Update: You can find info about character classes here.

Update2: Looking at wolfrevokcats reply, I see he made a valid observation and his solution is the safer one.

Upvotes: 0

wolfrevokcats
wolfrevokcats

Reputation: 2100

I see in your log file that timestamps of corresponding rows are different. So, I suppose, when two users log in at the same time, log records could get interspersed, for example:

<W>2016-06-25 00:27:30.577 1 => <4:(-1)> Client version 1.2.10 (Win: 1.2.10)
<W>2016-06-25 00:27:30.635 1 => <2:(-1)> Client version 1.2.16 (Win: 1.2.16)
<W>2016-06-25 00:27:30.635 1 => <4:[AAA] User1(1850)> Authenticated
<W>2016-06-25 00:27:30.687 1 => <2:[AAA] User2(942)> Authenticated

If this is the case, I would suggest using a hash to remember ids:

use strict;
use warnings;
my $file = 'mylogfile.log';
open (my $fl, '<:encoding(UTF-8)', $file)
        or die 'File not found';
my %ids;

while (my $row = <$fl>) {
        if ($row =~ m/\<(\d+).*\>\sclient\sversion\s(\d+.\d+.\d+)\s/i) {
        my ($id,$vers)=($1,$2);
        $ids{$id}=$vers;
    }
    elsif ($row =~ m/\<(\d+)\:(.+)\(\d+\)\>.*authenticated/i) {
        if (defined $ids{$1}) {
            print "$1 : $2 : $ids{$1}\n";
            delete $ids{$1};
        }
    }
}

Upvotes: 1

lexx9999
lexx9999

Reputation: 746

I don't know much about perl, but can provide some idea:

login= map();
while( row=readrow())
{
   if(match(id version))
     login[$1]=$2
   else
   if(match(id username userid ))
   {
     print "user: ", $2,  "version:",login[$1], "userid: $3", "sessionid: ", $1
     delete login[$1]
   }
}

Upvotes: 0

Related Questions