CODEWITHSUNDEEP
autocadautolisp
Floben Dale Moro
Floben Dale Moro

Reputation: 93

autolisp list used as points in Autocad

I'm new to LISP in autocad. The code shown below draws circles (with radius of 1) in a sloped line. What I don't understand is the value of "a" does not increase in increments of 1. The center of the circle drawn in autocad is (1,1) , (1.7071,1.7071) , (3,3) , (3.7071,3.7071) , (5,5) ... Can someone pls. explain why?

(defun c:wwq ()
    (setq a 0)
    (while (< a 10)
        (setq a (+ 1 a))   
        (setq pt1 (list a a ) ) 
        (command "circle" pt1 1 )    
    )
)

Upvotes: 2

Views: 709

Answers (1)

gileCAD
gileCAD

Reputation: 2493

While using the AutoLISP command function, you have to care about active object snaps. One way is to force object snaps to "none" within the (command ...) expression:

(defun c:wwq (/ a pt1)
  (setq a 0)
  (while (< a 10)
    (setq a (+ 1 a))
    (setq pt1 (list a a))
    (command "_circle" "_none" pt1 1)
  )
  (princ)
)

Or, you can deactivate every osnap by setting the OSMODE system variable to 0 at the begining of the code and retore the previous value at the end (to be really safe, this method should need and error handler to insure the the previous value is reset in case an error occur during the code execution).

(defun c:wwq (/ a pt1 os)
  (setq a  0
    os (getvar 'osmode)
  )
  (setvar 'osmode 0)
  (while (< a 10)
    (setq a (+ 1 a))
    (setq pt1 (list a a))
    (command "_circle" pt1 1)
  )
  (setvar 'osmode os)
  (princ)
)

Another way is to use the entmake function which is faster and do not care about osnaps.

(defun c:wwq (/ a)
  (setq a 0.0)
  (while (< a 10.0)
    (setq a (+ 1.0 a))
    (entmake
      (list
        (cons 0 "CIRCLE")
        (list 10 a a 0.0)
        (cons 40 1.0)
      )
    )
  )
  (princ)
)

Upvotes: 1

Related Questions