CODEWITHSUNDEEP
cmake
Julian Helfferich
Julian Helfferich

Reputation: 1310

CMake: Convert relative path to absolute path, with build directory as current directory

In CMake, you can convert relative paths to absolute paths using

get_filename_component(ABSOLUTE_PATH ${RELATIVE_PATH} ABSOLUTE)

However, paths such as ../../other_program/ are based on the source directory (i.e. the directory where the CMakeLists.txt files is), not the build directory (i.e. the directory from which cmake is called). This can lead to some confusion if you give a relative path as a command line option.

Is there a way to tell get_filename_component that it should base the relative path on the current binary dir instead of the current source dir?

Upvotes: 51

Views: 75594

Answers (4)

Torbjörn
Torbjörn

Reputation: 5800

From the docs of get_filename_component (highlighting be me) :

get_filename_component(<VAR> <FileName>
                      <COMP> [BASE_DIR <BASE_DIR>]
                      [CACHE])

Set <VAR> to the absolute path of <FileName>, where <COMP> is one of:

ABSOLUTE = Full path to file REALPATH = Full path to existing file with symlinks resolved

If the provided <FileName> is a relative path, it is evaluated relative to the given base directory <BASE_DIR>. If no base directory is provided, the default base directory will be CMAKE_CURRENT_SOURCE_DIR.

Paths are returned with forward slashes and have no trailing slashes. If the optional CACHE argument is specified, the result variable is added to the cache.

Thus, you can use:

get_filename_component(<out-var> "${myFile}"
                       REALPATH BASE_DIR "${CMAKE_BINARY_DIR}")

An different way to do the same is to use

file(REAL_PATH <path> <out-var> BASE_DIRECTORY "${CMAKE_BINARY_DIR}").

Upvotes: 57

Martin Cejp
Martin Cejp

Reputation: 773

CMake 3.20 comes with a new way to do this, using the cmake_path command:

cmake_path(ABSOLUTE_PATH <path-var> [BASE_DIRECTORY <input>] [NORMALIZE]
                                    [OUTPUT_VARIABLE <out-var>])

BASE_DIRECTORY defaults to CMAKE_CURRENT_SOURCE_DIR, but can be overriden.

Upvotes: 4

mike.dld
mike.dld

Reputation: 3049

You could check whether path is absolute with if(IS_ABSOLUTE path) and if it isn't prepend the base directory you want. For example,

if(NOT IS_ABSOLUTE ${p})
    set(p "${CMAKE_CURRENT_BINARY_DIR}/${p}")
endif()

Upvotes: 4

tvorez
tvorez

Reputation: 460

get_filename_component(MY_RESULT_ABSOLUTE_PATH_VAR
                       "${CMAKE_CURRENT_LIST_DIR}/${MY_RELATIVE_PATH_VAR}"
                       ABSOLUTE)

Upvotes: 28

Related Questions