CODEWITHSUNDEEP
perlanyevent
Todd
Todd

Reputation: 746

AnyEvent::STOMP::Client + AnyEvent::ForkManger = Intermittent Error

I'm trying to write a process that listens to ActiveMQ and based on the message, goes out and grabs data from a webservice, does some processing and then puts the process data to another webservice. (REST/JSON)

The module below works fine until one of the wonky webservices I talk to returns an error. I've tried many things to catch the error but to no avail, yet. Once the webservice error happens though I get the following message:

unhandled callback exception on event (MESSAGE, AnyEvent::STOMP::Client=HASH(0x3ad5e48), HASH(0x3a6bbb0) {"action":"created","data":{"id":40578737,"type":"alert","who":null},"guid":"ADCCEE0C-73A7-11E6-8084-74B346D1CA67","hostname":"myserver","pid":48632}): $fork_manager->start() should be called within the manager process

OK, I conceptually understand that child process is trying to start another process and that fork manager is saying that is a no no. But given the module below, what is the proper way to start a new process to handle the long running processing. Or why is an child process dying causing this exception and how can I prevent this

Here's the module (stripped down)

package consumer;

use AnyEvent::ForkManager;
use AnyEvent::STOMP::Client;
use JSON;
use Data::Dumper;
use v5.18;
use Moose;

sub run {
    my $self    = shift;
    my $pm      = AnyEvent::ForkManager->new(max_workers => 20);
    my $stomp   = AnyEvent::STOMP::Client->new();

    $stomp->connect();
    $stomp->on_connected(sub {
        my $stomp   = shift;
        $stomp->subscribe('/topic/test');
        say "Connected to STOMP";
    });

    $pm->on_start(sub {
        my ($pm,$pid,@params) = @_;
        say "Starting $pid worker";
    });

    $pm->on_finish(sub {
        my ($pm, $pid,@params) = @_;
        say "Finished $pid worker";
    });

    $pm->on_error(sub {
        say Dumper(\@_);
    });

    $stomp->on_message(sub {
        my ($stomp, $header, $body) = @_;
        my $href    = decode_json $body;
        $pm->start(cb => sub {
            my ($pm, @params) = @_;
            $self->process(@params);
        },
        args    => [ $href->{id}, $href->{data}->{type}, $href->{data}->{who} ],
        );
    });

    my $cv = AnyEvent->condvar;
    $cv->recv;
}

sub process {
    say "Processing ".Dumper(\@_);
    sleep 5;
    if ( int(rand(10)) < 5 ) {
        die "OOPS";  # this triggers the error message above
    }
    say "Done Processing $_[1]";
}

1;

Heres the driver for the module above:

#!/usr/bin/env perl

use v5.18;
use lib '.';
use consumer;

my $c   = consumer->new();
$c->run;

Finally a traffic generator that you can use to see this in action:

#!/usr/bin/env perl

use lib '../lib';
use lib '../../lib';
use v5.18;

use Data::Dumper;
use JSON;
use Net::STOMP::Client;

$ENV{'scot_mode'} = "testing";

my $stomp = Net::STOMP::Client->new(
    host    => "127.0.0.1",
    port    => 61613
);
$stomp->connect();

for (my $i = 1; $i < 1000000; $i++) {
    my $href    = {
        id      => $i,
        type    => "event",
        what    => "foo",
    };
    my $json    = encode_json $href;
    say "Sending ".Dumper($href);
    $stomp->send(
        destination => "/topic/test",
        body        => $json,
    );
}

$stomp->disconnect();

Upvotes: 2

Views: 98

Answers (1)

Todd
Todd

Reputation: 746

I was able to solve this by using Try::Catch and wrapping the call to self->process with a try catch like this:

$stomp->on_message(sub {
        my ($stomp, $header, $body) = @_;
        my $href    = decode_json $body;
        $pm->start(cb => sub {
            my ($pm, @params) = @_;
            try {
                $self->process(@params);
            }
            catch {
                # error handling stuff
            };
        },
        args    => [ $href->{id}, $href->{data}->{type}, $href->{data}->{who} ],
        );
    }
);

Upvotes: 1

Related Questions