delay sending mail with Exchange Web Services (EWS) Managed API

Question

My issue is I cannot seem to put a delay on sending the item (have tried 2 minutes through to 2 days, no luck).

The mail itself sends immediately and without fail - it's just the delay that doesn't work? any help would be appreciated.

Note -

• I have been using this as an example for most of my code.

• I am using exchange 2010 SP2

• The mail sends fine, just no delay

---

Public Class Mail
    Private Const DEFERREDSENDTIMEFLAG As Integer = 16367
    Public Shared ReadOnly Property EXCHANGESERVICEURL As String
        Get
            Return ConfigurationManager.AppSettings("EXCHANGESERVICEURL")
        End Get
    End Property
    Public Shared ReadOnly Property DOMAINNAME As String
        Get
            Return ConfigurationManager.AppSettings("DOMAINNAME")
        End Get
    End Property
    Public Shared ReadOnly Property EXCHANGEUSERNAME As String
        Get
            Return ConfigurationManager.AppSettings("EXCHANGEUSERNAME")
        End Get
    End Property
    Public Shared ReadOnly Property EXCHANGEPASSWORD As String
        Get
            Return ConfigurationManager.AppSettings("EXCHANGEPASSWORD")
        End Get
    End Property
    Public Shared ReadOnly Property EXCHANGEVERSION As ExchangeVersion
        Get
            Return CType(System.Enum.Parse(GetType(ExchangeVersion), ConfigurationManager.AppSettings("EXCHANGEVERSION")), ExchangeVersion)
        End Get
    End Property
    Public Shared Sub SendMessage(ByVal fromAddress As String, ByVal toAddress() As String, ByVal ccAddress() As String, ByVal bccAddress() As String, ByVal subject As String, ByVal body As String, ByVal minutesDelay As Integer)

        ServicePointManager.ServerCertificateValidationCallback = New RemoteCertificateValidationCallback(AddressOf ValidateCertificate)
        Dim service As New ExchangeService(EXCHANGEVERSION)
        service.Credentials = New WebCredentials(EXCHANGEUSERNAME, EXCHANGEPASSWORD, DOMAINNAME)
        service.Url = New Uri(EXCHANGESERVICEURL)

        Dim Message As New Microsoft.Exchange.WebServices.Data.EmailMessage(service)
        'set delay send time
        If minutesDelay > 0 Then
            Dim sendTime As String = DateTime.Now.AddMinutes(minutesDelay).ToUniversalTime().ToString()
            Dim PR_DEFERRED_SEND_TIME As New ExtendedPropertyDefinition(DEFERREDSENDTIMEFLAG, MapiPropertyType.SystemTime)
            Message.SetExtendedProperty(PR_DEFERRED_SEND_TIME, sendTime)
        End If
        Message.From = fromAddress
        If toAddress IsNot Nothing Then
            For Each t As String In toAddress
                Message.ToRecipients.Add(t)
            Next
        End If
        If ccAddress IsNot Nothing Then
            For Each t As String In ccAddress
                Message.CcRecipients.Add(t)
            Next
        End If
        If bccAddress IsNot Nothing Then
            For Each t As String In bccAddress
                Message.BccRecipients.Add(t)
            Next
        End If
        Message.Subject = subject
        Message.Body = body


        Message.SendAndSaveCopy() 'save means make sure it's saved in the sent items folder
        'message.Attachments
    End Sub

    Private Shared Function ValidateCertificate(sender As Object, certificate As X509Certificate, chain As X509Chain, sslPolicyErrors As SslPolicyErrors) As Boolean
        Return True
    End Function
End Class

Answer 1

I would suggest you used the typed variable rather then converting the Date-time to a string (like the example does) and then sending it. eg just use

Message.SetExtendedProperty(PR_DEFERRED_SEND_TIME, DateTime.Now.AddMinutes(minutesDelay).ToUniversalTime())

The library is designed to deal with typed variables but you can see the difference in the POST using a String vs Typed variable if you enable tracing eg

        <t:ExtendedProperty>
          <t:ExtendedFieldURI PropertyTag="16367" PropertyType="SystemTime"/>
          <t:Value>2016-05-10T03:20:16.000</t:Value>
        </t:ExtendedProperty>

vs

          <t:ExtendedProperty>
          <t:ExtendedFieldURI PropertyTag="16367" PropertyType="SystemTime"/>
          <t:Value>2016-10-05T03:12:30.067Z</t:Value>
        </t:ExtendedProperty>

You could also fix the string but using the typed varible makes more sense with that change you sample run fine for me.