CODEWITHSUNDEEP
modelingmodelica
Sara Usmani
Sara Usmani

Reputation: 1

is boiler component present in open modelica

I'm working on modeling thermal power plant. I am looking for boiler component in open modelica or ThermoPower library. Can you help me locate the boiler in modelica?

Upvotes: 0

Views: 703

Answers (1)

Rene Just Nielsen
Rene Just Nielsen

Reputation: 3403

There is no single boiler model present in ThermoPower or OpenModelica (Modelica Standard Library). However, most of the building blocks for a boiler model are available, depending on your needs:

A very simple boiler with feedwater pump could be written with a few code lines. E.g.

model SteamGenerator_ph 
  "Simple steam generator with prescribed live steam pressure and enthalpy"
  replaceable package Medium = Modelica.Media.Water.StandardWater;

  parameter Medium.AbsolutePressure p=1e7 "Live steam pressure";
  parameter Medium.SpecificEnthalpy h=3477e3 "Live steam enthalpy";
  parameter Real eta=0.9 "Boiler efficiency";
  Modelica.SIunits.HeatFlowRate Q_flow_fuel "Fuel heat flow rate";

  Modelica.Fluid.Interfaces.FluidPort_a inlet(redeclare package Medium = Medium);
  Modelica.Fluid.Interfaces.FluidPort_b outlet(redeclare package Medium = Medium);
equation 
  inlet.m_flow + outlet.m_flow = 0 "mass flow balance";

  // Energy balance
  actualStream(outlet.h_outflow)*outlet.m_flow + actualStream(inlet.h_outflow)*
    inlet.m_flow + Q_flow_fuel*eta = 0;
  inlet.h_outflow = outlet.h_outflow;

  outlet.p = p "Ideally controlled live steam pressure";
  outlet.h_outflow = h "Ideally controlled live steam enthalpy";
end SteamGenerator_ph;

It assumes ideally controlled live steam enthalpy and pressure so if you test it on its own you can't connect the outlet to a fixed pressure source. Instead you should fix the inlet pressure and the outlet mass flow rate. The model is very simple and might give you some problems when you close the Rankine circuit.

If you want a slightly more detailed boiler - and one that's easier to use with a turbine, preheaters etc. - you should simply use a heated pipe (boiler) connected with a (feedwater) pump and use two PI controllers to control live steam enthalpy and pressure with the pump and the heat flow rate into the pipe (see picture below). Again, since the live steam pressure is controlled you can't connect it to a pressure source.

enter image description here

Adding a drum+evaporator (if you are modelling a drum boiler) and a steam valve will add a bit more complexity but also flexibility in terms of testing the boiler model and connecting it to other components (se picture below for inspiration).

enter image description here

The evaporation component can be found in Modelica.Fluid.Examples.DrumBoiler.BaseClasses.EquilibriumDrumBoiler and is equivalent to the "simple" drum model in the ThermoPower library

Upvotes: 5

Related Questions