CODEWITHSUNDEEP
xmlxslt
Андрій Бойко
Андрій Бойко

Reputation: 91

Got problems with replacing xml nodes within text

I'm working on XML-to-XML transformation (Windows 10, Oxygen XML Editor) and got this task: replace <xref id="id1">text</xref> with id1.

I've done some work but can't get why doesn't scenario replace all xref-s in parentheses. Any ideas?

And just in case if somebody know how to remove parentheses outside of xref-s, please tell. I was trying concat('(',$temp,')') but it also skips parenteses and concat('(',$temp,';') even doesn't work.

Here the example (I keep punctuation just in case):

<section>
    <somenode>Lorem ipsum</somenode>
    <p>Lorem ipsum (<xref id="id1">TEXT1, 2014</xref>) dolor.</p>
    <p>Lorem ipsum (<xref id="id5">TEXT5., 2016</xref>) dolor.</p>
    <p>Lorem ipsum (<xref id="id6">TEXT6., 2004</xref>; <xref id="id7">TEXT7., 2014</xref>; <xref id="id8">TEXT8., 2012</xref>), dolor.</p>
    <p>Lorem ipsum (<xref id="id6">TEXT6., 2004</xref>; <xref id="id7">TEXT7., 2014</xref>; <xref id="id8">TEXT8., 2012</xref>), dolor.</p>
    ...
</section>
...

Here the result:

<section>
    <somenode>Lorem ipsum</somenode>
    <p>Lorem ipsum (id1) dolor.</p>
    <p>Lorem ipsum (id5) dolor.</p>
    <p>Lorem ipsum (id6; TEXT7., 2014; TEXT8., 2012), dolor.</p>
    <p>Lorem ipsum (TEXT6., 2004; id7; TEXT8., 2012), dolor.</p>
    ...
</section>
...

I expect:

<section>
    <somenode>Lorem ipsum</somenode>
    <p>Lorem ipsum (id1) dolor.</p>
    <p>Lorem ipsum (id5) dolor.</p>
    <p>Lorem ipsum (id6; id7; id8), dolor.</p>
    <p>Lorem ipsum (id6; id7; id8), dolor.</p>
    ...
</section>
...

and Here the scenario:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="2.0">
<xsl:output method="xml" encoding="UTF-8"/>
<xsl:template name="xrefs">
    <xsl:for-each select="section">
        <xsl:for-each select="p">
            <xsl:variable name="tempP">
                <xsl:value-of select="."/>
            </xsl:variable>
            <xsl:for-each select="xref">
                <xsl:variable name="temp">
                    <xsl:value-of select="."/>
                </xsl:variable>
                <xsl:value-of select="replace($tempP,$temp,./@id)"/>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:for-each>
</xsl:template>

<xsl:template match="/">
    <xsl:call-template name="xrefs"/>
</xsl:template>

Upvotes: 0

Views: 42

Answers (1)

michael.hor257k
michael.hor257k

Reputation: 116993

got this task: replace <xref id="id1">text</xref> with id1.

That could be done easily by:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="xref">
    <xsl:value-of select="@id"/>
</xsl:template>

</xsl:stylesheet>

Applies to the following well-formed (!) input example:

XML

<section>
    <somenode>Lorem ipsum</somenode>
    <p>Lorem ipsum (<xref id="id1">TEXT1, 2014</xref>) dolor.</p>
    <p>Lorem ipsum (<xref id="id5">TEXT5., 2016</xref>) dolor.</p>
    <p>Lorem ipsum (<xref id="id6">TEXT6., 2004</xref>; <xref id="id7">TEXT7., 2014</xref>; <xref id="id8">TEXT8., 2012</xref>), dolor.</p>
    <p>Lorem ipsum (<xref id="id6">TEXT6., 2004</xref>; <xref id="id7">TEXT7., 2014</xref>; <xref id="id8">TEXT8., 2012</xref>), dolor.</p>
    ...
</section>

the result will be:

<?xml version="1.0" encoding="UTF-8"?>
<section>
   <somenode>Lorem ipsum</somenode>
   <p>Lorem ipsum (id1) dolor.</p>
   <p>Lorem ipsum (id5) dolor.</p>
   <p>Lorem ipsum (id6; id7; id8), dolor.</p>
   <p>Lorem ipsum (id6; id7; id8), dolor.</p>
    ...
</section>

And just in case if somebody know how to remove parentheses outside of xref-s, please tell.

That could be achieved by adding these two templates (requires XSLT 2.0):

<xsl:template match="text()[following-sibling::*[self::xref]][ends-with(., '(')]">
    <xsl:value-of select="substring(., 1, string-length() - 1) "/>
</xsl:template>

<xsl:template match="text()[preceding-sibling::*[self::xref]][starts-with(., ')')]">
    <xsl:value-of select="substring(., 2) "/>
</xsl:template>

Then the result will be:

<?xml version="1.0" encoding="UTF-8"?>
<section>
   <somenode>Lorem ipsum</somenode>
   <p>Lorem ipsum id1 dolor.</p>
   <p>Lorem ipsum id5 dolor.</p>
   <p>Lorem ipsum id6; id7; id8, dolor.</p>
   <p>Lorem ipsum id6; id7; id8, dolor.</p>
    ...
</section>

Upvotes: 1

Related Questions