CODEWITHSUNDEEP
asp-classicsql-server-2016
Aaron Russell
Aaron Russell

Reputation: 75

Issue with migration using classic ASP

Having a problem with migration of a site from one server to another, here is the error I'm getting:

Microsoft Cursor Engine error '80040e21'

Multiple-step operation generated errors. Check each status value.

/common/classes/Cart.asp, line 110

Line 110 is:

fld.Value = Request(fld.Name)

Here is the code that's causing the issue:

public function InsertOrder
    set rs = Server.CreateObject("ADODB.Recordset")
    rs.ActiveConnection = OrdersConnectionString
    rs.Source = "SELECT *  FROM "& OrdersTable
    rs.CursorType = 3
    rs.CursorLocation = 3
    rs.LockType = 3
    rs.Open()
    rs.AddNew
    For Each fld in rs.Fields
    if Len(Request(fld.Name)) > 0 then
    fld.Value = Request(fld.Name)
    end if
    Next
    rs.Update
    rs.Requery
    rs.Sort=OrderKey &" desc "
    OrderID=rs(OrderKey)
end function

It used to use SQL2008 but the new server us running SQL2016.

Thanks for any ideas you can give.

Upvotes: 0

Views: 235

Answers (1)

Shadow Wizard
Shadow Wizard

Reputation: 66388

Judging from the code causing this error, this is most likely a problem with type casting behind the scenes. Somehow the database driver fails to properly convert the data to the proper type, so you have to do that yourself.

One way which is pretty flexible, is defining key/value pairs (VBScript Dictionary can fit in this case) where the key will be the field name, and the value will be the type to which to convert the value. (String, Integer, Double, Date)

Sample code would be: (untested, but should work as-is, provided you put correct details)

Const FIELD_TYPE_STRING = 1
Const FIELD_TYPE_INTEGER = 2
Const FIELD_TYPE_DOUBLE = 3
Const FIELD_TYPE_DATE = 4
Const FIELD_TYPE_CURRENCY = 5
Function ConverFieldValue(rawValue, fieldType)
    ConverFieldValue = VBNull
    Select Case fieldType
        Case FIELD_TYPE_STRING:
            ConverFieldValue = CStr(rawValue)
        Case FIELD_TYPE_INTEGER:
            If rawValue<>"" Then ConverFieldValue = CLng(rawValue)
        Case FIELD_TYPE_DOUBLE
            If rawValue<>"" Then ConverFieldValue = CDbl(rawValue):
        Case FIELD_TYPE_DATE:
            If rawValue<>"" Then ConverFieldValue = CDate(rawValue)
        Case FIELD_TYPE_CURRENCY:
            If rawValue<>"" Then ConverFieldValue = CCur(rawValue)
    End Select
End Function
Dim typeMapping
Set typeMapping = Server.CreateObject("Scripting.Dictionary")

'''***Add actual field names and types below:****
typeMapping.Add "Field1", FIELD_TYPE_STRING
typeMapping.Add "Field2", FIELD_TYPE_INTEGER
typeMapping.Add "Field3", FIELD_TYPE_DOUBLE
typeMapping.Add "Field4", FIELD_TYPE_CURRENCY
typeMapping.Add "Field5", FIELD_TYPE_DATE
'''*************************************************

Dim currentFieldType, currentFieldValue
Set rs = Server.CreateObject("ADODB.Recordset")
rs.ActiveConnection = OrdersConnectionString
rs.Source = "SELECT *  FROM "& OrdersTable
rs.CursorType = 3
rs.CursorLocation = 3
rs.LockType = 3
rs.Open()
rs.AddNew
For Each fld in rs.Fields
    if Len(Request(fld.Name)) > 0 then
        currentFieldType = typeMapping(fld.Name)
        currentFieldValue = ConverFieldValue(Request(fld.Name), currentFieldType)
        fld.Value = currentFieldValue
    end if
Next
rs.Update
rs.Requery
rs.Sort=OrderKey &" desc "
OrderID=rs(OrderKey)

Upvotes: 2

Related Questions