CODEWITHSUNDEEP
perl
x2m
x2m

Reputation: 91

Why do I get a different result when I do math on a quoted vs. non-quoted variable?

I am working with latitudes and longitudes to determine business locations and ran into some odd behavior.

In the Perl snippet below, the equation assigning data to $v1 evaluates to 1. When I call acos($v1), I receive a sqrt error. When I call acos("$v1") (with quotes), I do not. Calling acos(1) does not produce the error, either. Why do the quotes matter?

use strict;
use warnings 'all';

sub acos {
    my $rad = shift;
    return (atan2(sqrt(1 - $rad**2), $rad));
}

my $v1 = (0.520371764072297 * 0.520371764072297) +
         (0.853939826425894 * 0.853939826425894 * 1);

print acos($v1);   # Can't take sqrt of -8.88178e-16 at foo line 8.
print acos("$v1"); # 0

Upvotes: 8

Views: 134

Answers (1)

ThisSuitIsBlackNot
ThisSuitIsBlackNot

Reputation: 24073

$v1 is not exactly 1:

$ perl -e'
    $v1 = (0.520371764072297 * 0.520371764072297) +
          (0.853939826425894 * 0.853939826425894 * 1);
    printf "%.16f\n", $v1
'
1.0000000000000004

However, when you stringify it, Perl only keeps 15 digits of precision:

$ perl -MDevel::Peek -e'
    $v1 = (0.520371764072297 * 0.520371764072297) +
          (0.853939826425894 * 0.853939826425894 * 1);
    Dump "$v1"
'
SV = PV(0x2345090) at 0x235a738
  REFCNT = 1
  FLAGS = (PADTMP,POK,pPOK)
  PV = 0x2353980 "1"\0      # string value is exactly 1
  CUR = 1
  LEN = 16

Upvotes: 15

Related Questions