CODEWITHSUNDEEP
arduinoembedded
cc young
cc young

Reputation: 20213

In Arduino, how do you write to port when port is a variable?

Examples of writing to a port seem to always use the port number as a constant, eg,

 OCR2A = 180;

How do you write to the port when the port is unknown until run time. For example,

int port = (buttonPressed) ? 0x3b : 0x3c;
portWrite( port, 180 );

What I cannot find is the funtion portWrite(). Does something like that exist?

Upvotes: 2

Views: 1450

Answers (2)

frarugi87
frarugi87

Reputation: 2880

Robert's answer has some imprecise assertions and an incomplete answer.

Writing directly to port registers you can ruin other settings of the port and sometimes cause permanent damage to controller.

Can ruin other settings: true, you have to know what you are doing (for instance what pins are on the port you are manipulating, and know what are the functions you want to keep.

Can cause permanent damage: not really, or better not because of the port manipulation. If you wire a short circuit to ground and then set it as an output to 1, you can damage it whether you are using the port register or the digitalwrite. You have to be careful in both ways.

Now, returning to your problem, the enumeration is one way, but since the PORTB, PORTC, PORTD are just short name for values, you can set a variable and then use it to indirectly access it.

The type for this kind of variable is a volatile pointer to a byte (volatile means that write and read operations cannot be optimized by the compiler, since the value can change even between two operations):

volatile uint8_t *variablePortRegister;

You just have to load it with the address (so with the & symbol) of the register you want to change:

variablePortRegister = &PORTC;

then use the pointer to change the value

PORTC = 0x12;
            becomes
(*variablePortRegister) = 0x12;

This is a short example. For it to work, connect a LED with resistor on arduino pin 5 (bit 5 of PORTD). The LED on the board (labeled L) is connected to pin 13 (bit 5 of PORTB).

The sketch will make one of the two leds blink for five times, then switch to the other. Only port manipulation instructions are used, and you can find that the way to read the port is the same as the one to write it.

volatile uint8_t *myportreg;
unsigned long lastTime;
uint8_t counter;

void setup() {
  DDRB |= 0x20;
  DDRD |= 0x20;
  PORTB = 0;
  PORTD = 0;
  counter = 99; // trigger the register change immediately
}

void loop() {
  if (counter >= 10)
  {
    counter = 0;
    if (myportreg == &PORTD)
      myportreg = &PORTB;
    else
      myportreg = &PORTD;
  }
  if ((millis() - lastTime) > 500)
  {
    lastTime = millis();
    // change bit 5 of register
    *myportreg = 0x20 ^ (*myportreg);
    counter++;
  }
}

EDIT: as Robert pointed out, it's much better to "use" just the pins you need (in this case, bit 5 of port B and D) rather than setting the whole port; this way you minimize the risk of screwing up something else. This edit is already included in the above code, so the code is correct

Upvotes: 4

Luiz Menezes
Luiz Menezes

Reputation: 819

The port is a bit in one particular register. If you know the register and the position of the port in that particular register you can try this:

register = (1<<port) || register

to set the port to 1 and

register = (1<<port)^-1 && register

to set the port to 0.

Of course, you will need a switch somewhere to determine the register and the bit of the port in the register given the port name.

Upvotes: 0

Related Questions