Text box validation

Question

I am using many text boxes in a form. How do i validate them, In certain text boxes I have to use only text and in some I have to use only numbers. Is using ASCII is a right method or is there any easier method to do this. If so please let me know the coding.

Answer 1

Private Sub TxtEmployeenumber_KeyPress(sender As Object, e As KeyPressEventArgs) Handles TxtEmployeenumber.KeyPress
    Dim c As Char
    c = e.KeyChar
    If Not (Char.IsDigit(c) Or c = "." Or Char.IsControl(c)) Then
        e.Handled = True
        MsgBox("numeric texts only")

    End If
End Sub

Answer 2

i would like to share my text box validator..

    Dim errProvider As New ErrorProvider

' Verify that this field is not blank.
    Private Sub txtValidating(sender As Object,
    e As System.ComponentModel.CancelEventArgs) Handles _
    txtName.Validating, txtStreet.Validating, txtCity.Validating,
    txtState.Validating, txtZip.Validating
        ' Convert sender into a TextBox.
        Dim txt As TextBox = DirectCast(sender, TextBox)
        ' See if it’s blank.
        If (txt.Text.Length > 0) Then
            ' It’s not blank. Clear any error.
            errProvider.SetError(txt, “”)
        Else
            ' It’s blank. Show an error.
            errProvider.SetError(txt, “This field is required.”)
        End If
    End Sub


' See if any field is blank.
    Private Sub Form1_FormClosing(sender As Object,
    e As FormClosingEventArgs) Handles Me.FormClosing
        If (txtName.Text.Length = 0) Then e.Cancel = True
        If (txtStreet.Text.Length = 0) Then e.Cancel = True
        If (txtCity.Text.Length = 0) Then e.Cancel = True
        If (txtState.Text.Length = 0) Then e.Cancel = True
        If (txtZip.Text.Length = 0) Then e.Cancel = True
    End Sub

Answer 3

just go to the keyup event of text box and enter the following code

100% it will work

if(Not Char.IsNumber(Chrw(e.Keycode))) Then
    Messagebox.show ("only numeric values ")
    textbox1.text=""
end if                  

Answer 4

Agreed that Regular Expressions might be faster, but ... well, here's how I've done it. Basically, this code is for a UserControl which contains a label, a text box, and an error provider. It also has various other properties, but here's the bit which deals with validation.

I do use this on the TextChanged event, because I don't want the user to continue typing if it's an invalid character; the rule checking "eats" the invalid character.

Public Enum CheckType
    ctString = 0
    ctReal = 1
    ctDecimal = 2
    ctInteger = 3
    ctByte = 4
End Enum

Private mAllowNegative As Boolean = True
Private mAllowNull As Boolean = True
Private mCheckType As CheckType = CheckType.ctString

<System.Diagnostics.DebuggerStepThrough()> _
Private Sub TextBox1_TextChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TextBox1.TextChanged
    RuleCheckMe()
End Sub

<System.Diagnostics.DebuggerStepThrough()> _
Private Sub RuleCheckMe()
    '// Rule Checking
    If Me.TextBox1.TextLength = 0 Then
        If mAllowNull = False Then
            Me.epMain.SetError(Me.TextBox1, "You are required to provide this value.")
            Me.Valid = False
        Else
            Me.epMain.Clear()
            Me.Valid = True
        End If
    Else
        Select Case mCheckType
            Case CheckType.ctString
                If mInputMask.Length > 0 Then
                    'TODO: Figure out how to cope with input masks!
                    Me.Valid = True
                Else
                    Me.Valid = True
                End If
            Case Else   '// right now we're only testing for numbers...
                If Not IsNumeric(Me.TextBox1.Text) And Me.TextBox1.Text <> "." And Me.TextBox1.Text <> "-" Then
                    If Not String.IsNullOrEmpty(Me.TextBox1.Text) Then
                        Me.TextBox1.Text = Me.TextBox1.Text.Remove(Me.TextBox1.Text.Length - 1, 1)
                        Me.TextBox1.SelectionStart = Me.TextBox1.Text.Length
                    End If
                    Me.epMain.SetError(Me.TextBox1, "This field does not accept non-numeric values.")
                    Me.Valid = False
                ElseIf mAllowNegative = False And Me.TextBox1.Text.StartsWith("-") Then
                    Me.TextBox1.Text = Me.TextBox1.Text.Remove(Me.TextBox1.Text.Length - 1, 1)
                    Me.epMain.SetError(Me.TextBox1, "This field does not accept negative values.")
                    Me.Valid = False
                ElseIf mCheckType = CheckType.ctByte And CType(Me.TextBox1.Text, Integer) > 255 Then
                    Me.epMain.SetError(Me.TextBox1, "This field does not accept values greater than 255.")
                    Me.Valid = False
                Else
                    Me.epMain.Clear()
                    Me.Valid = True
                End If
        End Select
    End If
End Sub

<System.ComponentModel.Browsable(True), _
System.ComponentModel.DesignerSerializationVisibility(System.ComponentModel.DesignerSerializationVisibility.Visible), _
System.ComponentModel.EditorBrowsable(System.ComponentModel.EditorBrowsableState.Always), _
System.ComponentModel.Category("Data")> _
Public Property AllowNegative() As Boolean
    <System.Diagnostics.DebuggerStepThrough()> _
    Get
        Return mAllowNegative
    End Get
    <System.Diagnostics.DebuggerStepThrough()> _
    Set(ByVal value As Boolean)
        mAllowNegative = value
    End Set
End Property

<System.ComponentModel.Browsable(True), _
System.ComponentModel.DesignerSerializationVisibility(System.ComponentModel.DesignerSerializationVisibility.Visible), _
System.ComponentModel.EditorBrowsable(System.ComponentModel.EditorBrowsableState.Always), _
System.ComponentModel.Category("Data")> _
Public Property AllowNull() As Boolean
    <System.Diagnostics.DebuggerStepThrough()> _
    Get
        Return mAllowNull
    End Get
    <System.Diagnostics.DebuggerStepThrough()> _
       Set(ByVal value As Boolean)
        mAllowNull = value
    End Set
End Property

<System.ComponentModel.Browsable(True), _
System.ComponentModel.DesignerSerializationVisibility(System.ComponentModel.DesignerSerializationVisibility.Visible), _
System.ComponentModel.EditorBrowsable(System.ComponentModel.EditorBrowsableState.Always), _
System.ComponentModel.Category("Data")> _
Public Property DataTypeCheck() As CheckType
    <System.Diagnostics.DebuggerStepThrough()> _
    Get
        Return mCheckType
    End Get
    <System.Diagnostics.DebuggerStepThrough()> _
       Set(ByVal value As CheckType)
        mCheckType = value
    End Set
End Property

Answer 5

Above all other, don’t annoy the user. If I’m typing some text and the application prevents that (regardless of how it does that), I’m rightfully pissed off.

There are multiple values to handle this:

• Use a NumericUpDown or a Slider control instead of a text box for numeric values (in other words: use the correct control instead of a general-purpose control).

• Allow (more or less) arbitrary input and try to parse the user input in a meaningful way. For example, entering “+33 (0) 6 12-34-56” is an entirely meaningful format for a phone number in France. An application should allow that, and try to parse it correctly.

  Granted, this is the hardest way, but it provides the best user experience.

• Use the Validating event to validate input. This is automatically triggered whenever the user leaves the input control, i.e. when they have finished their input, and a validation will not annoy the user.

  The MSDN documentation of the event gives an example of how this event is used correctly.

But do not use the KeyPress or TextChanged events to do validation. The first will disturb the users when entering text. The second will also annoy them when they try to paste text from somewhere else. Imagine the following: I am trying to copy an number from a website. Unfortunately, the text I have copied includes something else, too, e.g. “eggs: 14.33 EUR” instead of just “14.33”.

Now, the application must give me the chance to paste and correct the text. If I am not allowed to do that, the application is a UX failure. If the application uses the TextChanged event to prevent my pasting this text, I don’t get the chance to delete the offending text.

Answer 6

Text only limited to 40 characters:

<asp:RegularExpressionValidator ID="regexpText" runat="server"     
                                ErrorMessage="Text only!" 
                                ControlToValidate="txtName"     
                                ValidationExpression="^[a-zA-Z]{1,40}$" />

Only Numbers:

<asp:RegularExpressionValidator ID="regexpNumber" runat="server"     
                                ErrorMessage="Numbers only!" 
                                ControlToValidate="txtName"     
                                ValidationExpression="^[0-9]$" />

Answer 7

The fastest way for validation is using regular expressions. They are harder to understand but offer better performance.

But you could do it also using string functions. Which is easier if you don't know regex but is less performant. This could be a viable option, depending on how hard the validation is.

Here and here are some posts that will help you with code samples.

Answer 8

Wow, this can be a very broad topic...

For numeric textboxes, you should probably restrict input during KeyPress event:

Private Sub TextBox1_KeyPress(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyPressEventArgs) Handles TextBox1.KeyPress

    Dim allowedChars As String = "0123456789"

    If allowedChars.IndexOf(e.KeyChar) = -1 Then
        ' Invalid Character
        e.Handled = True
    End If

End Sub

NOTE: This code sample is assuming WinForms, different approach must be used for web...

Regardless of the plat form, you should look into the validation controls offered by the framework, and that will allow you to validate that there is indeed input, values are in a specified range, and also using regex write more complicated validation rules.