sql server 2008 - find which tables contain specific text

Question

i have a database that has a few hundred tables

i need to find a specific string in any of the columns in all of the tables.

how would i approach this problem>??

Answer 1

Below is a copy of an answer to a similar question I already provided here (Search for a string in an all the tables, rows and columns of a SQLL Server DB)

’d suggest you find yourself a 3rd party tool for this such as ApexSQL Search (there are probably others out there too but I use this one because it’s free).

If you really want to go the SQL way you can try using stored procedure created by Sorna Kumar Muthuraj – copied code is below. Just execute this stored procedure for all tables in your schema (easy with dynamics SQL)

CREATE PROCEDURE SearchTables 
@Tablenames VARCHAR(500) 
,@SearchStr NVARCHAR(60) 
,@GenerateSQLOnly Bit = 0 
AS 

/* 
Parameters and usage 

@Tablenames        -- Provide a single table name or multiple table name with comma seperated.  
                    If left blank , it will check for all the tables in the database 
@SearchStr        -- Provide the search string. Use the '%' to coin the search.  
                    EX : X%--- will give data staring with X 
                         %X--- will give data ending with X 
                         %X%--- will give data containig  X 
@GenerateSQLOnly -- Provide 1 if you only want to generate the SQL statements without seraching the database.  
                    By default it is 0 and it will search. 

Samples : 

1. To search data in a table 

    EXEC SearchTables @Tablenames = 'T1' 
                     ,@SearchStr  = '%TEST%' 

    The above sample searches in table T1 with string containing TEST. 

2. To search in a multiple table 

    EXEC SearchTables @Tablenames = 'T2' 
                     ,@SearchStr  = '%TEST%' 

    The above sample searches in tables T1 & T2 with string containing TEST. 

3. To search in a all table 

    EXEC SearchTables @Tablenames = '%' 
                     ,@SearchStr  = '%TEST%' 

    The above sample searches in all table with string containing TEST. 

 4. Generate the SQL for the Select statements 

    EXEC SearchTables @Tablenames        = 'T1' 
                     ,@SearchStr        = '%TEST%' 
                     ,@GenerateSQLOnly    = 1 

*/ 

SET NOCOUNT ON 

DECLARE @CheckTableNames Table 
( 
Tablename sysname 
) 

DECLARE @SQLTbl TABLE 
( 
 Tablename        SYSNAME 
,WHEREClause    VARCHAR(MAX) 
,SQLStatement   VARCHAR(MAX) 
,Execstatus        BIT  
) 

DECLARE @sql VARCHAR(MAX) 
DECLARE @tmpTblname sysname 

IF LTRIM(RTRIM(@Tablenames)) IN ('' ,'%') 
BEGIN 

    INSERT INTO @CheckTableNames 
    SELECT Name 
      FROM sys.tables 
END 
ELSE 
BEGIN 

    SELECT @sql = 'SELECT ''' + REPLACE(@Tablenames,',',''' UNION SELECT ''') + '''' 

    INSERT INTO @CheckTableNames 
    EXEC(@sql) 

END 

INSERT INTO @SQLTbl 
( Tablename,WHEREClause) 
SELECT SCh.name + '.' + ST.NAME, 
        ( 
            SELECT '[' + SC.name + ']' + ' LIKE ''' + @SearchStr + ''' OR ' + CHAR(10) 
              FROM SYS.columns SC 
              JOIN SYS.types STy 
                ON STy.system_type_id = SC.system_type_id 
               AND STy.user_type_id =SC.user_type_id 
             WHERE STY.name in ('varchar','char','nvarchar','nchar') 
               AND SC.object_id = ST.object_id 
             ORDER BY SC.name 
            FOR XML PATH('') 
        ) 
  FROM  SYS.tables ST 
  JOIN @CheckTableNames chktbls 
            ON chktbls.Tablename = ST.name  
  JOIN SYS.schemas SCh 
    ON ST.schema_id = SCh.schema_id 
 WHERE ST.name <> 'SearchTMP' 
  GROUP BY ST.object_id, SCh.name + '.' + ST.NAME ; 

  UPDATE @SQLTbl 
     SET SQLStatement = 'SELECT * INTO SearchTMP FROM ' + Tablename + ' WHERE ' + substring(WHEREClause,1,len(WHEREClause)-5) 

  DELETE FROM @SQLTbl 
   WHERE WHEREClause IS NULL 

WHILE EXISTS (SELECT 1 FROM @SQLTbl WHERE ISNULL(Execstatus ,0) = 0) 
BEGIN 

    SELECT TOP 1 @tmpTblname = Tablename , @sql = SQLStatement 
      FROM @SQLTbl  
     WHERE ISNULL(Execstatus ,0) = 0 



     IF @GenerateSQLOnly = 0 
     BEGIN 

        IF OBJECT_ID('SearchTMP','U') IS NOT NULL 
            DROP TABLE SearchTMP 
        EXEC (@SQL) 

        IF EXISTS(SELECT 1 FROM SearchTMP) 
        BEGIN 
            SELECT Tablename=@tmpTblname,* FROM SearchTMP 
        END 

     END 
     ELSE 
     BEGIN 
         PRINT REPLICATE('-',100) 
         PRINT @tmpTblname 
         PRINT REPLICATE('-',100) 
         PRINT replace(@sql,'INTO SearchTMP','') 
     END 

     UPDATE @SQLTbl 
        SET Execstatus = 1 
      WHERE Tablename = @tmpTblname 

END 

SET NOCOUNT OFF 

go

Answer 2

I just posted to another question what in my opinion is the best solution to this given task.

My answer even address such comments as that from marc_s :-) (yep, we know about fulltext).

Hope you lone reader like it (I really need more reputation).

Answer 3

to find table columns use:

SELECT table_name=sysobjects.name,
         column_name=syscolumns.name
    FROM sysobjects 
    JOIN syscolumns ON sysobjects.id = syscolumns.id
    JOIN systypes ON syscolumns.xtype=systypes.xtype
   WHERE sysobjects.xtype='U'
ORDER BY sysobjects.name,syscolumns.colid

if you want data in the tables use dynamic sql you can do something on these lines:

Declare @Sql varChar(100)
Declare @Temp Table (Ind INT, TableName nvarchar(100))

Insert Into @Temp
Select Row_Number() Over(Order BY [Name]), [Name]
FROM
(
    Select [Name]
    from sys.tables
) AS D

Declare @index int
Set @index = 1
while @index < (Select Count(*) From @Temp)
begin
SET @SQL = ' Select * From ' + (Select TableName From @Temp Where Ind = @index)


exec (@SQL)
Set @index = @index + 1
End