ColdFusion 8: Convert OData Response to Array

Question

I'm attempting to update an existing CF8 application to consume and load an array with the results of a newly updated RESTful API response using OData.

Here's the code in question... After pulling the data from the API that responds with the OData jSON string, the code blows up on the last line that inits the loop

<!--- Returned data is in json format so must change to an array. --->
<cfset local.result = deserializeJSON(myResult)>

<!--- Reference the array collection of categories --->
<cfset local.collection = local.result>

<!--- Initialize the output object --->
<cfset local.output = arrayNew(1)>

<!--- Loop over the collection --->
<cfloop from="1" to="#arrayLen(local.collection)#" index="local.arrayIndex">
...

This was working fine using the previous JSON response:

[
  {
    "id": 1,
    "name": "Blah, blah",
  }
]

The only change introduced is the updated JSON response:

[
  {
     "@odata.context": "string",
     "value": [
      {
        "id": 1,
        "name": "Blah, blah"
      }
    ]
  }
]

I'm sure I'm missing something basic, but I've never worked on CF before so it's new territory here.

Thoughts?

Thanks!

UPDATE: Apologies on not providing more detail. Here's how the app currently uses the response:

<!--- Loop over the collection --->
<cfloop from="1" to="#arrayLen(local.collection)#" index="local.arrayIndex">

  <!--- Create a reference to the array element --->
  <cfset local.objectInstance = local.collection[local.arrayIndex]>

  <!--- Create a new object reference --->
  <cfset local.thisObject = structNew()>

  <!--- Seed the object properties --->
  <cfset local.thisObject.categoryId = local.objectInstance.id>
  <cfset local.thisObject.categoryName = local.objectInstance.name>

  <!--- Place the new object in the collection array --->
  <cfset arrayAppend(local.output, duplicate(local.thisObject))>

</cfloop>

And here's the error I'm receiving:

Error Occurred While Processing Request  
Object of type class coldfusion.runtime.Struct cannot be used as an array  

The error occurred in <path to file> line 97

"Line 97" is the begin loop available in the update above:

I did try using the "newJSON" approach offered by Miguel (thank you very much for that!), but unfortunately, I'm running into the same error.

Thanks again! -Rich

Answer 1

Update after user posted more information

If you are still getting an error then you did something wrong. You must change the way you are referencing the new JSON data object. I created a new Gist using the updated code that you supplied so you can see how it works - TryCF Gist 2

Basically the code within your <cfloop> needs to look like this. Again, notice that there are actually two <cfloop> blocks. This is because the new JSON format generates an array that contains another array.

<!--- Loop over the collection --->
<cfloop from="1" to="#arrayLen(local.collection)#" index="local.arrayIndex">

    <cfloop from="1" to="#arrayLen(local.collection[local.arrayIndex].value)#" index="local.arrayIndex2">

      <!--- Create a reference to the array element --->
      <cfset local.objectInstance = local.collection[local.arrayIndex].value>

      <!--- Create a new object reference --->
      <cfset local.thisObject = structNew()>

      <!--- Seed the object properties --->
      <cfset local.thisObject.categoryId = local.objectInstance[local.arrayIndex2].id>
      <cfset local.thisObject.categoryName = local.objectInstance[local.arrayIndex2].name>

      <!--- Place the new object in the collection array --->
      <cfset arrayAppend(local.output, duplicate(local.thisObject))>

    </cfloop>

</cfloop>

See the Gist for more details but this assigns the local.output array as it was before. In your original code the local.objectInstance within the loop was a structure. With the new JSON format the local.objectInstance within the loop now contains an array of structures. So you need to reference it as such.

Original answer before question was updated

With the updated JSON you will need to update how your code references the data (which you did not include in your original post). Making some assumptions I can show you how to reference the data using the examples you gave.

First for your original example. Here is some code that would reference and output the data for you. Notice that I have included a <cfdump> tag. You will want to use that in situations like this where you need to see the data. The deserializeJSON() function parses the JSON for you and creates a ColdFusion array of structures.

<cfset oldJSON = '[ { "id": 1, "name": "Blah, blah" } ]'>

<!--- Returned data is in json format so must change to an array. --->
<cfset local.result = deserializeJSON(oldJSON)>

<!--- Reference the array collection of categories --->
<cfset local.collection = local.result>

<!--- Initialize the output object --->
<cfset local.output = arrayNew(1)>

<cfdump var="#local.result#" label="Old JSON">

<!--- Loop over the collection --->
<cfoutput>
<cfloop from="1" to="#arrayLen(local.collection)#" index="local.arrayIndex">
    <p>#local.arrayIndex# - #local.collection[local.arrayIndex].id# - #local.collection[local.arrayIndex].name#</p>
</cfloop>
</cfoutput>

That code gives this output:

Here is an example of the updated code needed to retrieve the same values from the new JSON format. Notice that I added another cfloop to reference the data because there are now two arrays.

<cfset newJSON = '[ { "@odata.context": "string", "value": [ { "id": 1, "name": "Blah, blah" } ] } ]'>
<!--- Returned data is in json format so must change to an array. --->
<cfset local.result = deserializeJSON(newJSON)>

<!--- Reference the array collection of categories --->
<cfset local.collection = local.result>

<!--- Initialize the output object --->
<cfset local.output = arrayNew(1)>

<cfdump var="#local.result#" label="New JSON">

<!--- Loop over the collection --->
<cfoutput>
<cfloop from="1" to="#arrayLen(local.collection)#" index="local.arrayIndex">
    <cfloop from="1" to="#arrayLen(local.collection[local.arrayIndex].value)#" index="local.arrayIndex2">
        <p>#local.arrayIndex# - #local.arrayIndex2# - #local.collection[local.arrayIndex].value[local.arrayIndex2].id# - #local.collection[local.arrayIndex].value[local.arrayIndex2].name#</p>
    </cfloop>
</cfloop>
</cfoutput>

That code gives this output:

I created a gist with all of this code that you can play around with - TryCF Gist 1