CODEWITHSUNDEEP
delphidatasnap
lmengyew
lmengyew

Reputation: 371

How to return a dataset with nested datasets from datasnap server to client?

I use Delphi Berlin. I have a sample datasnap server return a dataset to client, the dataset contain TDataSetField.

The server method:

unit ServerMethodsUnit1;

//...

implementation

uses Datasnap.DBClient;

function TServerMethods1.GetDataSet: TDataSet;
var D: TClientDataSet;
    D1: TDataSet;
    F: TFieldDef;
begin
  D := TClientDataSet.Create(nil);
  D.FieldDefs.Add('DocKey', ftLargeint);
  D.FieldDefs.Add('DocNo', ftWideString, 20);
  D.FieldDefs.Add('Detail', ftDataSet);
  F := D.FieldDefs.Find('Detail');
  F.ChildDefs.Add('DtlKey', ftLargeint);
  F.ChildDefs.Add('DocKey', ftLargeint);
  F.ChildDefs.Add('Amount', ftBcd, 2);
  D.CreateDataSet;

  D.Append;
  D.FindField('DocKey').AsLargeInt := 1;
  D.FindField('DocNo').AsString := 'IV-00001';
  D1 := (D.FindField('Detail') as TDataSetField).NestedDataSet;
  D1.AppendRecord([1, 1, 123.12]);
  D1.AppendRecord([2, 1, 234.23]);
  D.Post;
  Result := D;
end;

end.

The client:

unit Unit1;

//...

procedure TForm1.Button1Click(Sender: TObject);
var C: TServerMethods1Client;
    D: TDataSet;
begin
  C := TServerMethods1Client.Create(SQLConnection1.DBXConnection);
  try
    D := C.GetDataSet;
    //...
  finally
    C.DisposeOf;
  end;
end;

When the client call TServerMethods1Client.GetDataSet method, the datasnap server return an error Feature not implemented. Any ideas of how to return a dataset contains nested datasets from datasnap server to client?

Upvotes: 0

Views: 2620

Answers (2)

lmengyew
lmengyew

Reputation: 371

I have found the solution.

The server method:

function TServerMethods1.GetDataSet: OleVariant;
//...
begin
  D := TClientDataSet.Create(nil);
  try
    //...   
    Result := D.Data;
  finally
    D.DisposeOf;
  end;
end;

The client: 

procedure TForm1.Button1Click(Sender: TObject);
var C: TServerMethods1Client;
begin
  C := TServerMethods1Client.Create(SQLConnection1.DBXConnection);
  try
    ClientDataSet1.Data := C.GetDataSet;
  finally
    C.DisposeOf;
  end;
end;

Upvotes: 2

Jefferson Rudolf
Jefferson Rudolf

Reputation: 161

I use DataSnap REST Application (Server) and DataSnap REST Client (Client). You can use TFDJSONDataSets (FireDac Reflect)

function TServerMethods1.GetDataSet: TFDJSONDataSets;
var 
  D: TClientDataSet;
  D1: TDataSet;
  F: TFieldDef;
begin
  D := TClientDataSet.Create(nil);
  D.FieldDefs.Add('DocKey', ftLargeint);
  D.FieldDefs.Add('DocNo', ftWideString, 20);
  D.FieldDefs.Add('Detail', ftDataSet);
  F := D.FieldDefs.Find('Detail');
  F.ChildDefs.Add('DtlKey', ftLargeint);
  F.ChildDefs.Add('DocKey', ftLargeint);
  F.ChildDefs.Add('Amount', ftBcd, 2);
  D.CreateDataSet;

  D.Append;
  D.FindField('DocKey').AsLargeInt := 1;
  D.FindField('DocNo').AsString := 'IV-00001';
  D1 := (D.FindField('Detail') as TDataSetField).NestedDataSet;
  D1.AppendRecord([1, 1, 123.12]);
  D1.AppendRecord([2, 1, 234.23]);
  D.Post;

  TFDJSONDataSetsWriter.ListAdd(Result,'DATASET',D);
end;

procedure TForm1.Button1Click(Sender: TObject);
var
 LDataSetList: TFDJSONDataSets;
 LDataSet: TFDDataSet;
begin     
  try
    LDataSet := TFDJSONDataSetsReader.GetListValueByName(LDataSetList, 'D');    
    if (oFDMemTable.Active) then
      oFDMemtable.Close;
    oFDMemTable.AppendData(LDataSet);
  except
    on E: TDSRestProtocolException do
      HandleRestException(ClientModule1.DSRestConnection, 'Error', E)
    else
      raise;
  end;  
end;

I pass some examples: http://docwiki.embarcadero.com/Libraries/Berlin/en/Data.FireDACJSONReflect.TFDJSONDataSets http://docwiki.embarcadero.com/RADStudio/Seattle/en/Tutorial:_Using_a_REST_DataSnap_Server_with_an_Application_and_FireDAC

Upvotes: 0

Related Questions