AS3 Socket/Server MMO Communication

Question

I'm working on a flash MMO with a c# server. I have a simple messaging protocol for the sockets. When a client joins he sends out this:

 "%|clientId|need"

And positions are updated like this:

 "$|clientId|xPosition|yPosition"

For some reason this isn't working. I store all the avatars in an array, the avatar class simply extends movieclip. This should add all clients into the room but it isn't working. Any ideas?

Edit: The error is probably in the client-side code above, I think it's with how I store the Avatars in an array.

Here is my code:

id.text = String(Math.random());
import flash.net.Socket;
import flash.events.MouseEvent;
import flash.utils.Timer;
import flash.events.TimerEvent;
import flash.utils.Dictionary;

var avatars:Array = new Array();

 var _socket:Socket = new Socket();
 _socket.addEventListener(ProgressEvent.SOCKET_DATA,socketData);
 _socket.addEventListener(Event.CONNECT,socketConnected);
 _socket.addEventListener(IOErrorEvent.IO_ERROR,socketError);



_socket.connect("192.168.1.4",8000);

function sendText(msg:String):void {
 if (_socket.connected) {
  _socket.writeUTFBytes(msg);
  _socket.flush();

 } else {

 }
}

function socketConnected(e:Event):void {
 chat.appendText("Connected. \n");
 sendText("%|" + id.text + "|need");
 //chat.scrollV = chat.maxScrollV;
}

function socketError(e:IOErrorEvent):void {
 chat.appendText("SYSTEM MSG:"+e.text+"\n");
 //chat.scrollV = chat.maxScrollV;
}

function socketData(e:ProgressEvent):void {
 var str:String = e.currentTarget.readUTFBytes(e.currentTarget.bytesAvailable);
 trace(str);
 //var xml:XML = new XML(str);
 chat.appendText(str + "\n");
 //[pos]|50|334
 if(str.search("$")){
  var positionArray = str.split("|");
  avatars[str[1]].x = str[2];
  avatars[str[1]].x = str[3];
 }
 if(str.search("%")){
  var miniArray = str.split("|");
  avatars[miniArray[1]] = new Avatar();
  addChild(avatars[miniArray[1]]);
  dump.text = miniArray[1];
 }

}



me.addEventListener(MouseEvent.MOUSE_DOWN, drag);
me.addEventListener(MouseEvent.MOUSE_UP, sDrag);

var timing:Boolean = false;
var t:Timer = new Timer(1);
t.addEventListener(TimerEvent.TIMER, tick);

function tick(e:TimerEvent){
 if(timing){
  sendText('$|'+id.text+'|'+me.x+'|'+me.y);
 }
 else{
 }
}

t.start();


function drag(e:MouseEvent){
 me.startDrag();
 timing = true;
}

function sDrag(e:MouseEvent){
 me.stopDrag();
 timing = false;
}

Answer 1

Edit: Changing answer based on additional information.

You had a few problems after addressing the code. First was your use of if(str.search)... The $ and % can be parsed as a regular expression. Additionally since your chars were at an index of 0 these if's could fail to be true. Lastly your were using str[1] instead of positionArray[1] etc. Below is the working code with some hacking to test without the use of a socket server. Might show you some tricks on how to do some focused testing when you run into issues like this.

package
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.events.ProgressEvent;

    public class TestSocket extends Sprite
    {
        import flash.events.MouseEvent;
        import flash.events.TimerEvent;
        import flash.net.Socket;
        import flash.utils.Dictionary;
        import flash.utils.Timer;

        [Embed(source="assets/avatar.png")]
        private var Avatar:Class;

        private var avatars:Array = new Array();

        function TestSocket():void
        {
            socketSimulator(10);
        }


        function socketData(e:ProgressEvent):void {
            var str:String = e.currentTarget.readUTFBytes(e.currentTarget.bytesAvailable);
            trace(str);

            if(str.indexOf("$") >= 0){
                var positionArray = str.split("|");
                avatars[positionArray[1]].x = positionArray[2];
                avatars[positionArray[1]].x = positionArray[3];
            }
            if(str.indexOf("%") >= 0){
                var miniArray = str.split("|");
                avatars[miniArray[1]] = new Avatar();
                addChild(avatars[miniArray[1]]);
            }

        }


        /** Test Code **/
        private var _numClients;

        private function socketSimulator(numClients:int):void
        {
            _numClients = numClients; 

            var msg:String;

            while(--numClients >= 0)
            {
                msg = "%|" + numClients + "|need";
                sendFakeData(msg);
            }

            var timer:Timer = new Timer(500, 9999);
            timer.addEventListener(TimerEvent.TIMER, sendFakeMovement);
            timer.start();
        }

        private function sendFakeMovement(e:TimerEvent):void
        {
            var id:uint = Math.random() * _numClients;
            var x:Number = Math.random() * 1000;
            var y:Number = Math.random() * 1000;
            var msg:String = "$|"+id+"|"+x+"|"+y;

            sendFakeData(msg);
        }

        //This is just hacked test code, don't do this in production
        private function sendFakeData(msg:String):void
        {
            var e:MyProgressEvent = new MyProgressEvent(ProgressEvent.SOCKET_DATA);
            e.currentTarget = {
                readUTFBytes: function(bytes:int = 0):String
                {
                    return msg;
                }
            }

            socketData(e);
        }
    }
}
import flash.events.ProgressEvent;

class MyProgressEvent extends ProgressEvent
{
    private var _currentTarget:Object;

    public function set currentTarget(val:Object):void
    {
        _currentTarget = val;
    }

    override public function get currentTarget():Object
    {
        return _currentTarget;
    }

    function MyProgressEvent(type:String):void
    {
        super(type);
    }
}

Answer 2

Before you test log in/log off/position, make sure that your architecture supports sending and receiving data in the first place, I mean, send a string ("some data") on the front-end and check if you're really receiving ("some data") on the back-end. I am afraid the byte endianness that you're sending on the client is different from that on the server and so the server will mis-understand the incoming data. If so you need to convert the incoming messages to the suitable endianness before trying to process them.