CODEWITHSUNDEEP
excelvbavbscriptexe
Arman
Arman

Reputation: 907

How to run a macro daily using windows task scheduler

I have a macro which I want to run at a specified time daily (say 11 am) even if Excel is closed.

What I have found out is that I can do it by creating Windows Task Scheduler, but I'm new to Windows and don't know how this is created.

The following is my macro:

Sub Mail_Sheet_Outlook_Body()

    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set rng = Nothing
    Set rng = ActiveSheet.UsedRange
    'You can also use a sheet name
    'Set rng = Sheets("YourSheet").UsedRange

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .To = ""
        .CC = ""
        .BCC = ""
        .Subject = "Testing"
        .HTMLBody = RangetoHTML(rng)
        .Send   'or use .Display
    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub


Function RangetoHTML(rng As Range)

    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

Can anyone tell me how to create the windows task scheduler to run this macro daily?

UPDATE:

Wrote the following vbs script:

Dim xlApp, xlBook

Set xlApp = CreateObject("Excel.Application")
xlApp.DisplayAlerts = False
Set xlBook = xlApp.Workbooks.Open(“H:\excel.xlsm”, 0, True)


xlApp.Run "GetFiles"

xlbook.Save
xlBook.Close False
set xlBook = Nothing

xlApp.Quit
Set xlApp = Nothing

WScript.Echo "Finished."
WScript.Quit

Upvotes: 0

Views: 3790

Answers (2)

Rajesh Sinha
Rajesh Sinha

Reputation: 197

Try this,,

Application.OnTime TimeValue("18:00:00"), "MyMacro"

Other if you want to run Macro without support of Excel,, U need to create Vbs file. It's like A.Vbs, ,, then open the file,, paste your sample Macro,, & the following lines are required to be added,,

objExcel.Application.Run "'path to excel file '! module name . macro name "

If you want to save it,, add this also, objExcel.Application.save objExcel.Application.Quit Then close & double click on the Vbs file.

Upvotes: 1

Dom Navratil
Dom Navratil

Reputation: 49

  1. Create a file and change extension to .vbs. You will be writing a small script to start open your xlsm file.
  2. Put your starting function in the Private Sub Workbook_Open(), so your function will run when the file is open
  3. Follow the instructions here to make Windows Task Scheduler fire off your vbs

Upvotes: 1

Related Questions