CODEWITHSUNDEEP
openglprocessingjogl
Bontempos
Bontempos

Reputation: 77

How to debug a GLException in Processing?

I am trying to implement a project related to projection mapping on processing using a custom projection matrix. I found an example that might give me a clue but it is too old and openGL and Processing change a lot meanwhile. I am not very familiar with shaders and openGL, but so far I could update the old code to the version I show below, so you can also compare with the original.

I am still getting a:

GLException: not a gl2 implementation

I am also a bit confused using PGL, GL, PG2 at same time. I feel this is not a good practice.

Original version of the code from Processing 1.0 forum is here.

This is the code I tried to update so far:

import com.jogamp.opengl.*;  
import java.nio.FloatBuffer;

float[] modelview = { 
  0.670984f, 0.250691f, 0.674993f, 0, -0.288247f, 
  0.966749f, -0.137371f, 0f, -0.68315f, -0.0505059f, 0.720934f, 0f, 
  0.164808f, 2.1425f, 32.9616f, 1f };
float[] proj = { 
  0.78125f, 0, 0, 0, 0, 1.04167f, 0, 0, 0, 0, -1.0002f, -1, 0, 
  0, -2.0002f, 0 };

FloatBuffer  mvbuf;
FloatBuffer  projbuf;

void setup() {
  size(1024, 768, P3D);
  PJOGL.profile = 2; //not sure if needed
  mvbuf = FloatBuffer.wrap(modelview);
  projbuf= FloatBuffer.wrap(proj);

  GLProfile glp = GLProfile.get(GLProfile.GL2);
  GLCapabilitiesImmutable glcaps = (GLCapabilitiesImmutable) new GLCapabilities(glp);
  GLCapabilities tGLCapabilities = new GLCapabilities(glp);
  println("System Capabilities:" + glcaps.toString());
  println("Profile Details: " + glp.toString());
  println("Is GL2 Supported?: " + glp.isGL2());
}

void draw() {
  background(0);

  PGL pgl = (PJOGL) beginPGL(); 
  GL gl = ((PJOGL) pgl).gl; 
  GL2 gl2 = gl.getGL2(); //GLException: not a GL2 implemantation 

  gl2.glMatrixMode(GL2.GL_PROJECTION);
  gl2.glLoadIdentity();
  gl2.glLoadMatrixf(projbuf);

  gl2.glMatrixMode(GL2.GL_MODELVIEW);
  gl2.glLoadIdentity();
  gl2.glLoadMatrixf(mvbuf);

  drawGrid(100, 10, gl2);

  endPGL(); //not sure if this is closing what it supposed to
}


void drawGrid(float len, float offset, GL2 g) {

  int nr_lines = (int)(len/offset);

  g.glColor3f(1, 1, 1);
  g.glBegin(g.GL_LINES);
  for (int i=-nr_lines; i<nr_lines; i++) {

    g.glVertex3f(i*offset, 0, -nr_lines*offset);
    g.glVertex3f(i*offset, 0, nr_lines*offset);
  }

  for (int i=-nr_lines; i<nr_lines; i++) {

    g.glVertex3f(-nr_lines*offset, 0, i*offset);
    g.glVertex3f(nr_lines*offset, 0, i*offset);
  }
  g.glEnd();
}

Upvotes: 1

Views: 474

Answers (1)

vallentin
vallentin

Reputation: 26207

First try this:

PGraphicsOpenGL pg = (PGraphicsOpenGL)g;
println(pg.OPENGL_VERSION);

What does it output? For me this would output:

4.5.0 NVIDIA 376.51

Thereby calling gl.getGL2() fails because an OpenGL 4.5 core context is not backwards compatible with an OpenGL 2.x context.

If I recall correctly then you do have to use PJOGL.profile and set it to 1, to get a backwards compatible context:

PJOGL.profile = 1;

Note that if you're using Processing 3.0, then you might have to utilize settings():

void settings() {
    size(1024, 768, P3D);
    PJOGL.profile = 1;
}

Upvotes: 1

Related Questions