XSLT Transformation with attributes

Question

i need to do xslt transformation based upon attributes from XML.For all the attributes with ed-Cover.i need to create coverage tag in target xml and map the elements in to it as child elements.Can you please help me

Input XML:

<c>
<m p='ed-Cover'></m>
<m p='premum-amt' v='100'></m>
<m p='premium-rate' v='10'></m>
<m p='prem-date' v='10-04-15'></m>
<m p='ed-Cover'></m>
<m p='premum-amt' v='50'></m>
<m p='premium-rate' v='5'></m>
<m p='prem-date' v='12-03-15'></m>
<m p='ed-Cover'></m>
<m p='premum-amt' v='75'></m>
<m p='premium-rate' v='7'></m>
<m p='prem-date' v='3-05-15'></m>
</c>

XSLT:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/">
  <coverages>
<xsl:for-each select="c/m">
</xsl:for-each>
 </coverages>
 </xsl:template>
</xsl:stylesheet>

Expected Output:

<coverages>
<coverage>
<coverage-prem-amt>100</coverage-prem-amt>
<coverage-prem-rate>10</coverage-prem-rate>
<coverage-prem-date>10-04-15</coverage-prem-date>
</coverage>
<coverage>
<coverage-prem-amt>50</coverage-prem-amt>
<coverage-prem-rate>5</coverage-prem-rate>
<coverage-prem-date>12-03-15</coverage-prem-date>
</coverage>
<coverage>
<coverage-prem-amt>75</coverage-prem-amt>
<coverage-prem-rate>7</coverage-prem-rate>
<coverage-prem-date>3-05-15</coverage-prem-date>
</coverage>
<coverages>

Answer 1

As you want a coverage element for m element with "ed-Cover" as the attribute value, you should change your xsl:for-each to this

  <xsl:for-each select="c/m[@p='ed-Cover']">

To get the values you require, which are siblings of this element, it might help to have a key so you can lookup the other elements based on the first "ed-Cover" that precedes them

<xsl:key name="cover" match="m" use="generate-id(preceding-sibling::m[@p='ed-Cover'][1])" />

So, to get the premium amount for the current "ed-Cover" you could do this

 <xsl:variable name="id" select="generate-id()" />

 <coverage-prem-amt>
    <xsl:value-of select="key('cover', $id)[@p='premum-amt']/@v" />
 </coverage-prem-amt>

Try this XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:key name="cover" match="m" use="generate-id(preceding-sibling::m[@p='ed-Cover'][1])" />

  <xsl:template match="/">
    <coverages>
      <xsl:for-each select="c/m[@p='ed-Cover']">
        <xsl:variable name="id" select="generate-id()" />
         <coverage>
           <coverage-prem-amt>
             <xsl:value-of select="key('cover', $id)[@p='premum-amt']/@v" />
           </coverage-prem-amt>
           <coverage-prem-rate>
             <xsl:value-of select="key('cover', $id)[@p='premium-rate']/@v" />
           </coverage-prem-rate>
           <coverage-prem-date>
             <xsl:value-of select="key('cover', $id)[@p='prem-date']/@v" />
           </coverage-prem-date>
         </coverage>
      </xsl:for-each>
    </coverages>
  </xsl:template>
</xsl:stylesheet>

EDIT: If you don't want to create elements if the values are not present, try a template approach

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:key name="cover" match="m" use="generate-id(preceding-sibling::m[@p='ed-Cover'][1])" />

  <xsl:template match="/">
    <coverages>
      <xsl:for-each select="c/m[@p='ed-Cover']">
        <xsl:variable name="id" select="generate-id()" />
         <coverage>
           <xsl:apply-templates select="key('cover', $id)[@p='premum-amt']" />
           <xsl:apply-templates select="key('cover', $id)[@p='premium-rate']" />
           <xsl:apply-templates select="key('cover', $id)[@p='prem-date']" />
         </coverage>
      </xsl:for-each>
    </coverages>
  </xsl:template>

  <xsl:template match="m[@p='premum-amt']">
    <coverage-prem-amt>
      <xsl:value-of select="@v" />
    </coverage-prem-amt>
  </xsl:template>  

  <xsl:template match="m[@p='premium-rate']">
    <coverage-prem-rate>
      <xsl:value-of select="@v" />
    </coverage-prem-rate>
  </xsl:template>

  <xsl:template match="m[@p='prem-date']">
    <coverage-prem-date>
      <xsl:value-of select="@v" />
    </coverage-prem-date>
  </xsl:template>
</xsl:stylesheet>

Answer 2

This would work too:

  <xsl:template match="c">
    <xsl:element name="coverages">
      <xsl:apply-templates select="m[@p='premum-amt']"/>
    </xsl:element>
  </xsl:template>

  <xsl:template match="m[@p='premum-amt']">
    <xsl:element name="coverage">
      <xsl:element name="coverage-prem-amt">
        <xsl:value-of select="@v"/>
      </xsl:element>
      <xsl:element name="coverage-prem-rate">
        <xsl:value-of select="following-sibling::m[@p='premium-rate'][1]/@v"/>
      </xsl:element>
      <xsl:element name="coverage-prem-date">
        <xsl:value-of select="following-sibling::m[@p='prem-date'][1]/@v"/>
      </xsl:element>
    </xsl:element>
  </xsl:template>