CODEWITHSUNDEEP
apache-flexclass
huff
huff

Reputation: 2014

Copying an instance of a class

Ok, ObjectUtil.copy is a good technique for copying Objects. But after having a lot of problems using it to copy other classes, I guess it is not the solution I'm after.

How would you approach the copying/cloning of instances of a class that you've defined? Maybe defining a function withing the class to copy it?

It is cool that most variables are passed by reference in flex, but sometimes is annoying not having control over this (sorry, I'm too used to plain C).

Thanks!

UPDATE:

To be more precise, as I can't make the ObjectUtil.copy() work with a custom class is... is there a way to copy, by using serialization, a custom class? Did you use successfully a ByteArray copy with a custom class?

Thanks for all the replies.

Upvotes: 3

Views: 2782

Answers (4)

yohairosen
yohairosen

Reputation: 1685

ObjectUtil.copy uses ByteArray internally to create a copy. In order for the copy to be successful, ByteArray requires that the flash player will be aware of you custom class. You do that by registering your class using the global registerClassAlias method.

For example:

//one time globally to the application.
registerClassAlias(getQualifiedClassName(CustomClass), CustomClass); 

//then
var c1:CustomClass = new CustomClass();
c1.name = "customClass";
var c2:CustomClass = ObjectUtil.copy(c1);

trace(ObjectUtil.toString(c1))
trace(ObjectUtil.toString(c2))

Upvotes: 3

Courtney Christensen
Courtney Christensen

Reputation: 9555

If you have control over the whole class hierarchy, I recommend implementing a clone() interface in every class. It's tedious, but will pay off as complexity increases.

(Forgive me if the syntax is a bit off, it's been a while)

// define a "cloneable" interface
public interface ICloneable {
  function clone() : Object;
}

For every class, implement the method...

public class MyClass1 implements ICloneable {
  ...
  public function clone() : Object {
    var copy:MyClass1 = new MyClass1();

    // copy member variables... if it is a user-defined object,
    // make sure you call its clone() function as well.

    return copy;
  }
}

To create a copy of the object, simply invoke the clone() function.

var copy:MyClass1 = original.clone();

As a side note, both Java and .NET seem to have adopted the clone methods on their base Object classes. I know of no analogous method for ActionScript's Object class.

Upvotes: 2

Courtney Christensen
Courtney Christensen

Reputation: 9555

If you determine that implementing a clone interface is not the correct approach in your situation, I suggest looking at the ByteArray object. I haven't used it myself, but it appears to give you all the control you should need over individual bytes. You can reading and writing from and to any object.

Senocular does a quick overview of it here.

function clone(source:Object):* {
  var copier:ByteArray = new ByteArray();
  copier.writeObject(source);
  copier.position = 0;
  return(copier.readObject());
}

Good luck!

Upvotes: 3

Michael Brewer-Davis
Michael Brewer-Davis

Reputation: 14276

Two common idioms:

  • a clone method
  • a copy constructor

Both of these let you define what exactly making a copy means--you may want some things copied shallowly and others deeply.

Upvotes: 0

Related Questions