CODEWITHSUNDEEP
neo4jcypher
Avenger789
Avenger789

Reputation: 402

How to create relationship based on common Epochtime property

I am trying to do a model for state changes of a batch. I capture the various changes and I have an Epoch time column to track these. I managed to get this done with the below code : 

MATCH(n:Batch), (n2:Batch) 
WHERE n.BatchId = n2.Batch
WITH n, n2 ORDER BY n2.Name
WITH n, COLLECT(n2) as others
WITH n, others, COALESCE(
    HEAD(FILTER(x IN others where x.EpochTime > n.EpochTime)),
    HEAD(others)
    ) as next
CREATE (n)-[:NEXT]->(next)
RETURN n, next;

It makes my graph circular because of the HEAD(others) and doesn't stop at the Node with the maximum Epoch time. If I remove the HEAD(others) then I am unable to figure out how to stop the creation of relationship for the last node. Not sure how to put conditions around the creation of relationship so I can stop creating relationships when the next node is null

Upvotes: 0

Views: 65

Answers (1)

cybersam
cybersam

Reputation: 66999

This might do what you want:

MATCH(n:Batch)
WITH n ORDER BY n.EpochTime
WITH n.BatchId AS id, COLLECT(n) AS ns
CALL apoc.nodes.link(ns, 'NEXT')
RETURN id, ns;

It orders all the Batch nodes by EpochTime, and then collects all the Batch nodes with the same BatchId value. For each collection, it calls the apoc procedure apoc.nodes.link to link all its nodes together (in chronological order) with NEXT relationships. Finally, it returns each distinct BatchId and its ordered collection of Batch nodes.

Upvotes: 1

Related Questions