CODEWITHSUNDEEP
puppetredhat
JaneD
JaneD

Reputation: 199

Puppet : Copy files only IF the package needs to be installed to the latest

I'm a puppet beginner - so bear with me :) I'm trying to write a module that does the following :

I've come up with the following :

class somepackage(
  $package_files_base = "/var/tmp",
  $package_setup      = "/var/tmp/package-setup.sh",
  $ndc_file           = "/var/tmp/somefile.ndc",
  $osd_file           = "/var/tmp/somefile.osd",
  $nds_file           = "/var/tmp/somefile.nds",
  $configini_file     = "/var/tmp/somefile.ini",
  $required_files     = ["$package_setup", "$ndc_file", "$osd_file",  $nds_file", "$configini_file"])
{
  package { 'some package':
    ensure  => 'latest',
    notify  =>  Exec['Package Setup'],
  }

  file { 'Package Setup Files':
    path    => $package_files_base,
    ensure  => directory,
    replace => false,
    recurse => true,
    source  => "puppet:///modules/somepackage/${::domain}",
    mode    => '0755',
  }

  exec { 'Package Setup':
    command     => "$package_setup",
    logoutput   => true,
    timeout     => 1800,
    require     => [ File['Package Setup Files']],
    refreshonly => true,
    notify      => Exec['Remove config files'],
  }

  exec { 'Remove config files':
    path        => ['/usr/bin','/usr/sbin','/bin','/sbin'],
    command     => "rm \"${package_setup}\" \"${ndc_file}\" \"${osd_file}\" \"${nds_file}\" \"${configini_file}\"",
    refreshonly => true,
  }
}

While this achieves most of what I want to do, I notice that upon rerunning puppet apply the files, although they were being removed, were being recopied.

I can understand why this happens, but I don't know how to code it so that the files get copied ONLY if the package gets updated/installed (e.g. package wasn't installed or old). Otherwise the files will get copied over and over again every time puppet runs every 30 min (default setup) on the client I assume... I tried using the replace => false to prevent this but that just means the files wont ever get removed from /var/tmp after the first run of the class, because it only prevents subsequent runs of the class to re-copy the files (from my testing). This does prevent the redundant, repetitive copying - however I just want the files to be gone the first time!

Is this possible? Head hurts :(

Thanks in advance! We're running Puppet version 3.8.6 on EL7.3.

EDIT: To be clear, this is the bit that I'm struggling with: the resource file { 'Package Setup Files':. This keeps getting files copied even though the package isn't updated/installed. How do I prevent this from happening?

Upvotes: 3

Views: 2621

Answers (1)

Alex Harvey
Alex Harvey

Reputation: 15472

Here are some suggestions.

1) Recommendation for a short term solution

Stop trying to clean up those files if you do not need to. Put them in /opt and forget about them. Better still, have Puppet place a README file in there with them that will explain to your future self and to your fellow admins what they are and why they are there.

While I completely understand the desire to clean up, you need to weigh the cost of having a few old files in a directory somewhere against the cost of having complicated logic in the Puppet code that will not make any sense to anyone in a few months.

This is what I would do and in my experience it is also what most Puppet module authors do with these sorts of set up files.

2) Consider an orchestration framework

That said, it appears to me that you are trying to use Puppet to do operational tasks, and while it can kind of do operational tasks (via features like ensure => latest etc) it is really intended to be a configuration management tool.

I recommend people use Puppet to ensure => installed for packages (make sure Puppet can install the app properly if you need to fully rebuild the node); then delegate the problem of applying version upgrades and hotfixes etc outside of Puppet.

There are a few reasons for this.

Puppet is a declarative configuration management system; your Puppet code should define an end-state. Puppet is not like a shell script, where instead of an end-state, you define steps that change the state of a server imperatively, "one step at a time".

The first problem with ensure => latest is philosophical. latest does not define a single end-state. The behaviour of your code at time X is different from the behaviour at time Y. So your code is not idempotent.

The second problem is practical. You can never solve the problem of RPM updates in a general way using Puppet, because Puppet can never know about all of the RPMs and their dependencies in your system. So, one way or another, you still need a specialised tool for managing the version updates.

So, since you will need a specialised tool for managing the version updates anyway, it is cleaner to draw a clear boundary between the two tools' roles: always use Puppet to manage the configuration and the initial installation; and then always use the other tool to manage the updates.

Ok, great. I see in your comments that you already have a Red Hat Satellite server, and you have written:

...some hosts within the Satellite have got an older version of the software within yum. But we don't update this software very often.....maybe once every year.

So, it sounds like you are using Puppet here to work around a problem in the way you are using Satellite. Is it possible to address this by fixing the way you use Satellite? If so, I think that will be cleaner.

Of course, sometimes the right thing to do is use a work-around, and that's why I provided some other options.

3) If you really really want Puppet to clean up those files

Perhaps move the logic inside a shell script. Something like:

class somepackage {

  $shell =

'#!/bin/bash

# maybe use wget instead of puppet to get the files
wget http://a.b/c.tgz
tar zxf c.tgz

# install stuff

# clean up stuff
'

  file { '/usr/local/bin/installer.sh':
    ensure  => file,
    mode    => '0755',
    content => $shell,
  }

  package { 'some package':
    ensure => latest,
    notify => Exec['installer'],
  }

  exec { 'installer':
    command     => '/usr/local/bin/installer.sh',
    refreshonly => true,
    require     => File['/usr/local/bin/installer.sh'],
  }
}

Upvotes: 2

Related Questions