CODEWITHSUNDEEP
shellcsh
RobbieTheK
RobbieTheK

Reputation: 198

C-shell syntax: Too many ('s. warning in .cshrc

Is the problem in the PATH section? When I try to fix the PATH with setenv I then get:

set: Variable name must begin with a letter.

Here is a snip of the file:

setenv MAIL /usr/spool/mail/$USER
setenv MATLABPATH /home/users/me/matlab/functions:/home/users/me/matlab/scripts
setenv PYTHONPATH /home/users/me/python/modules:/home/users/me/python/scripts
set path=( /sbin /bin /usr/bin /usr/local/bin /usr/local/java/bin
           /usr/bin/X11 ~/bin)
if (! $?csh) then
   if($?prompt) then
        set prmptchr=$prompt
   else
        set prmptchr="/"
   endif
   alias setprompt 'set prompt = "$cwd$prmptchr "' # directory name in prompt
   alias cd 'chdir \!*; setprompt'
   alias pushd 'pushd \!*; setprompt'
   alias popd 'popd \!*; setprompt'
   setprompt
endif

Upvotes: 1

Views: 3326

Answers (1)

RobbieTheK
RobbieTheK

Reputation: 198

Here are the 2 issues corrected:

setenv MAIL /usr/spool/mail/$USER
setenv MATLABPATH /home/users/me/matlab/functions:/home/users/me/matlab/scripts 
setenv PYTHONPATH /home/users/me/python/modules:/home/users/me/python/scripts

# Added \ to split across multiple lines
set path=( /sbin /bin /usr/bin /usr/local/bin /usr/local/java/bin \
           /usr/bin/X11 ~/bin)
if (! $?csh) then
   if($?prompt) then
        # Added " around $prompt to make sure it's quoted correctly.
        set prmptchr="$prompt"
   else
        set prmptchr="/"
   endif
   alias setprompt 'set prompt = "$cwd$prmptchr "' # directory name in prompt
   alias cd 'chdir \!*; setprompt'
   alias pushd 'pushd \!*; setprompt'
   alias popd 'popd \!*; setprompt'
   setprompt
endif

Upvotes: 1

Related Questions