CODEWITHSUNDEEP
cassandracql
Rabindra
Rabindra

Reputation: 31

Cassandra - Data Insert into nested collection type using CQL

I need some help on inserting data in a table (with nested collection TYPE) columns.

I am getting the following error:

Error from server: code=2200 [Invalid query] message="Unknown field 'icon_id' in value of user defined type tst_diag_msg_typ"

Thanks in advance for your help !!

Here is what I am doing:

CREATE TYPE cs_veh.tst_icon_typ (
   icon_id text,
   icon_val text
);


CREATE TYPE cs_veh.tst_diag_msg_typ (
   msg_id text,
   msg_priority int,
   msg_text text,
   IconReason SET <FROZEN<tst_icon_typ>> 
);


CREATE TABLE test_veh_health
(VIN text,
eventtimestamp timestamp,
DiagnosticMessages SET < FROZEN <tst_diag_msg_typ>>,
PRIMARY KEY((VIN),eventtimestamp ))
WITH CLUSTERING ORDER BY (eventtimestamp DESC);
insert into test_veh_health
( VIN,
  eventtimestamp
, DiagnosticMessages 
)
values
('TEST122227751',
 toTimestamp(now())
,{{msg_id : '24.0:ENGINE:MESSAGE', msg_priority : 37, msg_text : 'Oil pressure: Engine off! See owners manual.' }
, { icon_id : 'xx',    icon_val: 'text'}
}
);

Upvotes: 3

Views: 856

Answers (1)

Ashraful Islam
Ashraful Islam

Reputation: 12840

Try the below insert statement : 

INSERT INTO test_veh_health(vin, eventtimestamp, diagnosticmessages) VALUES (
    'TEST122227751', 
    toTimestamp(now()),
    {
      {
        msg_id : '24.0:ENGINE:MESSAGE', 
        msg_priority : 37, 
        msg_text : 'Oil pressure: Engine off! See owners manual.' , 
        iconreason : { 
          {
            icon_id : 'xx',
            icon_val: 'text'
          }
        }
      }
    }
);

Output : 

cqlsh:test> SELECT * FROM test_veh_health ;

@ Row 1
--------------------+----------------------------------------------------------------------------------------------------------------------------------------------------------------
 vin                | TEST122227751
 eventtimestamp     | 2017-08-11 19:07:27.545000+0000
 diagnosticmessages | {{msg_id: '24.0:ENGINE:MESSAGE', msg_priority: 37, msg_text: 'Oil pressure: Engine off! See owners manual.', iconreason: {{icon_id: 'xx', icon_val: 'text'}}}}

@ Row 2
--------------------+----------------------------------------------------------------------------------------------------------------------------------------------------------------
 vin                | TEST122227751
 eventtimestamp     | 2017-08-11 18:54:57.519000+0000
 diagnosticmessages | null

Upvotes: 1

Related Questions