CODEWITHSUNDEEP
excelexcel-formulaconcatenation
David Provest
David Provest

Reputation: 25

Concatenate a column of data (ignoring blanks) and separating data with line break

Looking to concatenate the data in column A to column C as shown in the attached image. (Note: column C is currently hard-coded)

Any help would be greatly appreciated, thanks.

enter image description here

Upvotes: 0

Views: 161

Answers (2)

Sixthsense
Sixthsense

Reputation: 1975

Or

Function TEXTJOIN(arr, Optional sDelim As String = ", ", Optional blSkipBlank As Boolean = True)
Dim lPos As Long, sResult As String

arr = Application.Transpose(arr)

sResult = Join(arr, sDelim)

If blSkipBlank = True Then
    sResult = Replace(sResult, sDelim & sDelim, sDelim)

    Do
        sResult = Replace(sResult, sDelim & sDelim, sDelim)
        lPos = InStr(1, sResult, sDelim & sDelim, vbTextCompare)
        If lPos = 0 Then Exit Do
    Loop
End If

If Right(sResult, Len(sDelim)) = sDelim Then
    TEXTJOIN = Left(sResult, Len(sResult) - Len(sDelim))
Else
    TEXTJOIN = sResult
End If

End Function

=TEXTJOIN(A1:A16)

Or

=TEXTJOIN(A1:A16,CHAR(10))

Upvotes: 0

Scott Craner
Scott Craner

Reputation: 152555

use TEXTJOIN()

=TEXTJOIN(char(10),TRUE,A1:A6)

Text Join was introduced with Office 365 Excel. If you do not have it then put this code in a module attached to the workbook and use the formula as described above:

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))
End Function

Upvotes: 3

Related Questions